Funktionsreferenz

GUICtrlCreateAvi

Erstellt ein AVI Video-Control für die GUI.

GUICtrlCreateAvi ( filename, subfileid, left, top [, width [, height [, style [, exStyle]]]] )

 

Parameter

filename Der Dateiname des Videos. Nur .avi-Dateien werden unterstützt.
subfileid Die ID des Subfiles, das verwendet werden soll. Besteht die Datei nur aus einem Video, ist -1 zu verwenden.
left Die linke Seite des Controls. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet.
top Die Oberkante des Controls. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet.
width [optional] Die Breite des Controls (voreingestellt ist die zuvor verwendete Breite).
height [optional] Die Höhe des Controls (voreingestellt ist die zuvor verwendete Höhe).
style [optional] Legt den Stil des Controls fest. Siehe Anhang GUI-Stile für Controls.

Standard (-1) : $ACS_TRANSPARENT
$ACS_TRANSPARENT wird immer verwendet, solange nicht $ACS_NONTRANSPARENT spezifiziert ist.
exStyle [optional] Legt den erweiterten Stil des Controls fest. Siehe Tabelle der erweiterten Stile.

 

Rückgabewert

Erfolg: Gibt die Identifikationsnummer (Control-ID) des neuen Controls zurück.
Fehler: Gibt 0 zurück.

 

Bemerkungen

Um den Wert des Controls zu erhalten, siehe GUICtrlRead.
Um Informationen im Control zu setzen oder zu verändern, siehe GUICtrlUpdate....

Um das Video zu starten, sobald das Control erzeugt wurde, verwendet man den Stil $ACS_AUTOPLAY.
Man kann die Animation starten und stoppen, indem man den Status mit GUICtrlSetState auf 1 oder 0 setzt. Siehe Beispiel.

Um weitere Stile zusätzlich zum Standardstil zu verwenden, ist BitOr($GUI_SS_DEFAULT_AVI, newstyle,...) zu benutzen.

Um die oben angegebenen Werte verwenden zu können, muss #include <AVIConstants.au3> in das Skript eingefügt werden.

Als Standard für das Verhalten des Controls (bzgl. Größe und/oder Position) bei Größenänderung der GUI gilt $GUI_DOCKSIZE. (Größe wird nicht geändert.)
Mögliche Resizing-Parameter siehe GUICtrlSetResizing.

- - - - - - - - Erklärung der Controls - - - - - - - -

 

Verwandte Funktionen

GUICoordMode (option), GUICtrlUpdate..., GUIGetMsg

 

Beispiel


#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $ani1, $buttonstart, $buttonstop, $msg

    GUICreate("Meine GUI-Animation", 360, 200)
    $ani1 = GUICtrlCreateAvi(@SystemDir & "\shell32.dll", 165, 50, 10)

    $buttonstart = GUICtrlCreateButton("Start", 95, 150, 70, 22)
    $buttonstop = GUICtrlCreateButton("Stopp", 195, 150, 70, 22)

    GUISetState()

    ; Die Schleife wiederholt sich, bis der Benutzer eine Beenden-Aktion auslöst
    While 1
        $msg = GUIGetMsg()

        Select
            Case $msg = $GUI_EVENT_CLOSE
                ExitLoop

            Case $msg = $buttonstart
                GUICtrlSetState($ani1, 1)

            Case $msg = $buttonstop
                GUICtrlSetState($ani1, 0)

        EndSelect
    WEnd
EndFunc   ;==>Example