Funktionsreferenz

GUICtrlCreateButton

Erstellt einen Button für die GUI.

GUICtrlCreateButton ( "text", left, top [, width [, height [, style [, exStyle]]]] )

Parameter

text Die Aufschrift des Buttons.
left Die linke Seite des Controls. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet.
top Die Oberkante des Controls. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet.
width [optional] Die Breite des Controls (Standard: Länge des Textes).
height [optional] Die Höhe des Controls (Standard: Höhe des Textes).
style [optional] Legt den Stil des Controls fest. Siehe Anhang GUI-Stile für Controls.

Standard ( -1) : Keine.
Erzwungener Stil : $WS_TABSTOP
exStyle [optional] Legt den erweiterten Stil des Controls fest. Siehe Tabelle der erweiterten Stile.

Rückgabewert

Erfolg: Gibt die Identifikationsnummer (Control-ID) des neuen Controls zurück.
Fehler: Gibt 0 zurück.

Bemerkungen

Um Informationen im Control zu setzen oder zu verändern, siehe GUICtrlUpdate....

Ein Button kann ein Icon oder Bild anzeigen, wenn man den Stil $BS_ICON oder $BS_BITMAP verwendet. Es ist GUICtrlSetImage zu benutzen, um das zu verwendende Bild festzulegen.

Um weitere Stile zusätzlich zum Standardstil zu verwenden, ist BitOr($GUI_SS_DEFAULT_BUTTON, newstyle,...) zu verwenden.

Um die oben angegebenen Werte verwenden zu können, muss #include <ButtonConstants.au3> in das Skript eingefügt werden.

Als Standard für das Verhalten des Controls (bzgl. Größe und/oder Position) bei Größenänderung der GUI gilt $GUI_DOCKSIZE. (Größe wird nicht geändert.)
Mögliche Resizing-Parameter siehe GUICtrlSetResizing.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg

Beispiel


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $Button_1, $Button_2, $msg
    GUICreate("Mein GUI Button") ; Erstellt ein GUI-Fenster welches mittig ausgerichtet wird

    Opt("GUICoordMode", 2)
    $Button_1 = GUICtrlCreateButton("Notepad ausführen", 10, 30, 100)
    $Button_2 = GUICtrlCreateButton("Button Test", 0, -1)

    GUISetState() ; Zeigt eine Dialogbox mit 2 Buttons an

    ; Die Schleife wiederholt sich, bis der Benutzer eine Beenden-Aktion auslöst
    While 1
        $msg = GUIGetMsg()
        Select
            Case $msg = $GUI_EVENT_CLOSE
                ExitLoop
            Case $msg = $Button_1
                Run('Notepad.exe') ; Öffnet Notepad
            Case $msg = $Button_2
                MsgBox(0, 'Test', 'Button 2 wurde gedrückt') ; Zeigt, dass Button2 gedrückt wurde
        EndSelect
    WEnd
EndFunc   ;==>Example