Funktionsreferenz

GUICtrlCreateCombo

Erstellt eine Liste mit ausklappbarer Auswahl (ComboBox) für die GUI.

GUICtrlCreateCombo ( "text", left, top [, width [, height [, style [, exStyle]]]] )

 

Parameter

text Der Text, der in der Liste erscheinen soll.
left Die linke Seite des Controls. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet.
top Die Oberkante des Controls. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet.
width [optional] Die Breite des Controls (voreingestellt ist die zuvor verwendete Breite).
height [optional] Die Höhe des Controls (voreingestellt ist die zuvor verwendete Höhe).
style [optional] Legt den Stil des Controls fest. Siehe Anhang GUI-Stile für Controls.

Standard (-1) : $CBS_DROPDOWN, $CBS_AUTOHSCROLL, $WS_VSCROLL
Erzwungene Stile : $WS_TABSTOP
exStyle [optional] Legt den erweiterten Stil des Controls fest. Siehe Tabelle der erweiterten Stile.

 

Rückgabewert

Erfolg: Gibt die Identifikationsnummer (Control-ID) des neuen Controls zurück.
Fehler: Gibt 0 zurück.

 

Bemerkungen

Um den Wert des Controls zu erhalten siehe GUICtrlRead.
Um Informationen im Control zu setzen oder zu verändern siehe GUICtrlUpdate....

Unter Windows XP/2003 wird Windows selbst die Größe der geöffneten Auswahlbox anpassen. In anderen Windows-Versionen kann man diese Größe mit dem "height"-Parameter definieren, falls der Standardwert nicht ausreichend groß ist, um mindestens eine Zeile darzustellen.

Um weitere Stile zusätzlich zum Standardstil zu verwenden ist BitOr(($GUI_SS_DEFAULT_COMBO, newstyle,...) zu benutzen.

Um die oben angegebenen Werte verwenden zu können, muss #include <ComboConstants.au3> in das Skript eingefügt werden.

Als Standard für das Verhalten des Controls (bzgl. Größe und/oder Position) bei Größenänderung der GUI gilt $GUI_DOCKHEIGHT. (Die Höhe wird nicht geändert.)
Mögliche Resizing-Parameter siehe GUICtrlSetResizing.

- - - - - - - - Erklärung der Controls - - - - - - - -

 

Verwandte Funktionen

GUICoordMode (Option), GUICtrlSetData, GUICtrlUpdate..., GUIGetMsg

 

Beispiel


#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $msg
    GUICreate("Meine GUI combo") ; Erstellt ein GUI-Fenster welches mittig ausgerichtet wird

    GUICtrlCreateCombo("item1", 10, 10) ; Erstellt das erste Item
    GUICtrlSetData(-1, "item2|item3", "item3") ; Fügt andere Items hinzu und setzt einen neuen Standard

    GUISetState()

    ; Die Schleife wiederholt sich, bis der Benutzer eine Beenden-Aktion auslöst
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc   ;==>Example