Funktionsreferenz

GUICtrlCreateGroup

Erstellt ein Gruppen-Control für die GUI.

GUICtrlCreateGroup ( "text", left, top [, width [, height [, style [, exStyle]]]] )

 

Parameter

text Die Beschriftung der Gruppe.
left Die linke Seite des Controls. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet.
top Die Oberkante des Controls. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet.
width [optional] Die Breite des Controls (voreingestellt ist die zuvor verwendete Breite).
height [optional] Die Höhe des Controls (voreingestellt ist die zuvor verwendete Höhe).
style [optional] Legt den Stil des Controls fest. Siehe Anhang GUI-Stile für Controls.
Standard ( -1) : keine.
Erzwungene Stile : $WS_GROUP, $BS_GROUPBOX.
exStyle [optional] Legt den erweiterten Stil des Controls fest. Siehe Tabelle der erweiterten Stile.

 

Rückgabewert

Erfolg: Gibt die Identifikationsnummer (Control-ID) des neuen Controls zurück.
Fehler: Gibt 0 zurück.

 

Bemerkungen

Ein Gruppen-Item ist die dünne Linie um Controls herum (üblicherweise nur bei Radiobuttons), die diese Items visuell zu Gruppen zusammenfasst. Innerhalb einer Gruppe kann immer nur einer der Radiobuttons ausgewählt sein.
Wenn mehrere Gruppen ohne eine sichtbare Linie erzeugt werden sollen, ist GUIStartGroup() zum Gruppieren der Radiobuttons zu benutzen.

Um die oben angegebenen Werte verwenden zu können, muss #include <ButtonConstants.au3> in das Skript eingefügt werden.

Als Standard für das Verhalten des Controls (bzgl. Größe und/oder Position) bei Größenänderung der GUI gilt $GUI_DOCKAUTO. (Größe und Position werden entsprechend dem neuen Fenster angepasst.)
Mögliche Resizing-Parameter siehe GUICtrlSetResizing.

- - - - - - - - Erklärung der Controls - - - - - - - -

 

Verwandte Funktionen

GUICoordMode (Option), GUIStartGroup

 

Beispiel


#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $radio_1, $radio_2, $msg

    GUICreate("Meine GUI mit der Gruppierfunktion") ; Erstellt ein GUI-Fenster welches mittig ausgerichtet wird

    GUICtrlCreateGroup("Gruppe 1", 190, 60, 90, 140)
    $radio_1 = GUICtrlCreateRadio("Radio 1", 210, 90, 60, 20)
    $radio_2 = GUICtrlCreateRadio("Radio 2", 210, 110, 60, 50)
    GUICtrlCreateGroup("", -99, -99, 1, 1) ; Gruppe schliessen

    GUISetState() ; Zeigt eine leere Dialogbox an

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc   ;==>Example