Funktionsreferenz

GUICtrlCreateInput

Erstellt eine Eingabe-Dialogbox für die GUI.

GUICtrlCreateInput ( "text", left, top [, width [, height [, style [, exStyle]]]] )

 

Parameter

text (Vorgeblendeter) Text in dem Input-Control.
left Die linke Seite des Controls. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet.
top Die Oberkante des Controls. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet.
width [optional] Die Breite des Controls (voreingestellt ist die zuvor verwendete Breite).
height [optional] Die Höhe des Controls (voreingestellt ist die zuvor verwendete Höhe).
style [optional] Legt den Stil des Controls fest. Siehe Anhang GUI-Stile für Controls.

Standard ( -1) : $ES_LEFT, $ES_AUTOHSCROLL
Erzwungene Stile : $WS_TABSTOP, nur wenn nicht $ES_READONLY gesetzt wurde. $ES_MULTILINE wird immer zurückgesetzt.
exStyle [optional] Legt den erweiterten Stil des Controls fest. Siehe Tabelle der erweiterten Stile.

 

Rückgabewert

Erfolg: Gibt die Identifikationsnummer (Control-ID) des neuen Controls zurück.
Fehler: Gibt 0 zurück.

 

Bemerkungen

Um den Wert des Controls zu erhalten, siehe GUICtrlRead.
Um Informationen im Control zu setzen oder zu verändern, siehe GUICtrlUpdate....

Um ein Input-Control zur Eingabe von Passwörtern zu erzeugen (die Eingabe wird unsichtbar durch einen Stern dargestellt), benutzt man den Stil $ES_PASSWORD.

Will man per drag & drop einen Dateinamen auf ein solches Control ziehen, muss man nur den erweiterten Stil WS_EX_ACCEPTFILES auf den Befehl GUICreate() anwenden und den Status auf $GUI_DROPACCEPTED setzen.
Hat man mehrere Drag and Drop-Dateien in diesem Control, kann man diese, durch "|" getrennte Dateien, mit GuiCtrlRead auslesen.

Um die oben angegebenen Werte verwenden zu können, muss #include <EditConstants.au3> in das Skript eingefügt werden.

Als Standard für das Verhalten des Controls (bzgl. Größe und/oder Position) bei Größenänderung der GUI gilt $GUI_DOCKHEIGHT. (Die Höhe wird nicht geändert.)
Mögliche Resizing-Parameter siehe GUICtrlSetResizing.

- - - - - - - - Erklärung der Controls - - - - - - - -

 

Verwandte Funktionen

GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg, GUICtrlRead, GUICtrlCreateUpdown, GUICtrlSetLimit

 

Beispiel


#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $file, $btn, $msg

    GUICreate("Meine GUI die Dateien akzeptiert", 320, 120, @DesktopWidth / 2 - 160, @DesktopHeight / 2 - 45, -1, 0x00000018); WS_EX_ACCEPTFILES
    $file = GUICtrlCreateInput("", 10, 5, 300, 20)
    GUICtrlSetState(-1, $GUI_DROPACCEPTED)
    GUICtrlCreateInput("", 10, 35, 300, 20) ; Akzeptiert kein Drag&Drop von Dateien
    $btn = GUICtrlCreateButton("Ok", 40, 75, 60, 20)

    GUISetState()

    $msg = 0
    While $msg <> $GUI_EVENT_CLOSE
        $msg = GUIGetMsg()
        Select
            Case $msg = $btn
                ExitLoop
        EndSelect
    WEnd

    MsgBox(4096, "Drag&Drop Datei", GUICtrlRead($file))
EndFunc   ;==>Example