Funktionsreferenz

GUICtrlCreateList

Erstellt ein List-Control für die GUI.

GUICtrlCreateList ( "text", left, top [, width [, height [, style [, exStyle]]]] )

 

Parameter

text Die Beschriftung des Controls.
left Die linke Seite des Controls. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet.
top Die Oberkante des Controls. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet.
width [optional] Die Breite des Controls (voreingestellt ist die zuvor verwendete Breite).
height [optional] Die Höhe des Controls (voreingestellt ist die zuvor verwendete Höhe).
style [optional] Legt den Stil des Controls fest. Siehe Anhang GUI-Stile für Controls.

Standard ( -1) : $LBS_SORT, $WS_BORDER, $WS_VSCROLL
Erzwungene Stile : $WS_TABSTOP, $LBS_NOTIFY
exStyle [optional] Legt den erweiterten Stil des Controls fest. Siehe Tabelle der erweiterten Stile.

 

Rückgabewert

Erfolg: Gibt die Identifikationsnummer (Control-ID) des neuen Controls zurück.
Fehler: Gibt 0 zurück.

 

Bemerkungen

Um den Wert des Controls zu erhalten, siehe GUICtrlRead.
Um Informationen im Control zu setzen oder zu verändern, siehe GUICtrlUpdate....

Die unterschiedlichen, auswählbahren Listeneinträge können mit GUICtrlSetData gesetzt werden.

Um das horizontale Scrollen zu begrenzen, ist GUICtrlSetLimit zu benutzen.

Um weitere Stile zusätzlich zum Standardstil zu verwenden, benutzt man BitOr($GUI_SS_DEFAULT_LIST, newstyle,...).

Um die oben angegebenen Werte verwenden zu können, muss #include <ListBoxConstants.au3> in das Skript eingefügt werden.

Als Standard für das Verhalten des Controls (bzgl. Größe und/oder Position) bei Größenänderung der GUI gilt $GUI_DOCKAUTO. (Größe und Position werden entsprechend dem neuen Fenster angepasst.)
Mögliche Resizing-Parameter siehe GUICtrlSetResizing.

- - - - - - - - Erklärung der Controls - - - - - - - -

 

Verwandte Funktionen

GUICoordMode (Option), GUICtrlSetData, GUICtrlSetLimit, GUICtrlUpdate..., GUIGetMsg

 

Beispiel


#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $MESSAGE = "Folgende Buttons wurden gedrückt:"
    Local $add, $clear, $mylist, $close, $msg

    GUICreate("Meine GUI List") ; Erstellt ein GUI-Fenster welches mittig ausgerichtet wird

    $add = GUICtrlCreateButton("Hinzufügen", 64, 32, 75, 25)
    $clear = GUICtrlCreateButton("Leeren", 64, 72, 75, 25)
    $mylist = GUICtrlCreateList("Buttons, die gedrückt wurden", 176, 32, 221, 97)
    GUICtrlSetLimit(-1, 200) ; Horizontales Scrollen begrenzen
    GUICtrlSetData(-1, $MESSAGE)
    $close = GUICtrlCreateButton("Mein Beenden-Button", 64, 160, 175, 25)

    GUISetState()

    $msg = 0
    While $msg <> $GUI_EVENT_CLOSE
        $msg = GUIGetMsg()

        Select
            Case $msg = $add
                GUICtrlSetData($mylist, "Du hast Button Nr. 1 gedrückt|")
            Case $msg = $clear
                GUICtrlSetData($mylist, "")
            Case $msg = $close
                MsgBox(0, "", "Der Beenden-Button wurde gedrückt", 2)
                Exit
        EndSelect
    WEnd
EndFunc   ;==>Example