Funktionsreferenz

GUICtrlCreateListViewItem

Erstellt einen Eintrag in einer mehrspaltigen Liste (ListView)

GUICtrlCreateListViewItem ( "text", listviewID )

Parameter

text Die Texte der einzelnen Spalten welche durch ein Trennzeichen getrennt. Das Trennzeichen kann mit Opt("GUIDataSeparatorChar") bestimmt werden.
listviewID Die Control-ID des ListView-Controls, zu dem der Eintrag hinzugefügt wird.

Rückgabewert

Erfolg: Gibt die Identifikationsnummer (Control-ID) des neuen Controls zurück.
Fehler: Gibt 0 zurück.

Bemerkungen

Diese Funktion erzeugt die einzelnen ListView-Einträge, die der Benutzer auswählen kann.

Die einzelnen Einträge funktionieren wie normale Controls und können mit GUICtrlSetData belegt werden.
Einträge können wie jedes andere Control durch GUICtrlDelete gelöscht werden.
Die ListView-Einträge können per Drag & Drop in jedes Edit- oderInput-Control gezogen werden, das den Status $GUI_ACCEPTFILES hat.
Siehe GUICtrlCreateListView zur Veränderung der Größe der Spalten.

Das spezielle Flag $GUI_BKCOLOR_LV_ALTERNATE kann zusammen mit dem ListView-Control dazu genutzt werden, den ListviewItems-Zeilen abwechselnd andere Hintergrundfarben zu geben.
Die ungeraden Zeilen bekommen die Farbe, welche durch GUICtrlSetBkColor des ListView-Controls zugewiesen wird.
Die geraden Zeilen bekommen die Farbe, welche durch GUICtrlSetBkColor des ListViewItem Controls zugewiesen wird.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

GUICtrlCreateListView, GUICtrlSetData, GUICtrlSetState, GUICtrlDelete, GUIGetMsg, GUICtrlRead, GUIDataSeparatorChar (Option)

Beispiel


#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $listview, $button, $item1, $item2, $item3, $msg

    GUICreate("Listview Einträge", 220, 250, 100, 200, -1, $WS_EX_ACCEPTFILES)
    GUISetBkColor(0x00E0FFFF) ; Ändert die Hintergrundfarbe

    $listview = GUICtrlCreateListView("Spalte1  |Spalte2|Spalte3", 10, 10, 200, 150);,$LVS_SORTDESCENDING)
    $button = GUICtrlCreateButton("Wert?", 75, 170, 70, 20)
    $item1 = GUICtrlCreateListViewItem("Eintrag2|Spalte22|Spalte23", $listview)
    $item2 = GUICtrlCreateListViewItem("Eintrag1|Spalte12|Spalte13", $listview)
    $item3 = GUICtrlCreateListViewItem("Eintrag3|Spalte32|Spalte33", $listview)
    GUICtrlCreateInput("", 20, 200, 150)
    GUICtrlSetState(-1, $GUI_DROPACCEPTED) ; Erlaubt drag&drop
    GUISetState()
    GUICtrlSetData($item2, "EINTRAG1")
    GUICtrlSetData($item3, "||SPALTE33")
    GUICtrlDelete($item1)

    Do
        $msg = GUIGetMsg()

        Select
            Case $msg = $button
                MsgBox(0, "Listview Einträge", GUICtrlRead(GUICtrlRead($listview)), 2)
            Case $msg = $listview
                MsgBox(0, "Listview", "angeklickt=" & GUICtrlGetState($listview), 2)
        EndSelect
    Until $msg = $GUI_EVENT_CLOSE
EndFunc   ;==>Example