Erstellt eine Menüleiste für die GUI.
GUICtrlCreateMenu ( "submenutext" [, menuID [, menuentry]] )
Parameter
| submenutext | Der Untermenü-Text. |
| menuID | [optional] Wenn die ID angegeben wird, erlaubt sie das Erstellen eines Untermenüs im entsprechenden Menü. Wenn die ID auf -1 gesetzt ist, bezieht sie sich auf die oberste Menü-Ebene. |
| menuentry | [optional] Ermöglicht es, die Nummer des Eintrags festzulegen, der erzeugt werden soll. Die Einträge sind beginnend mit 0 durchnummeriert. |
Rückgabewert
| Erfolg: | Gibt die Identifikationsnummer (Control-ID) des neuen Controls zurück. |
| Fehler: | Gibt 0 zurück. |
Bemerkungen
Um Informationen im Control zu setzen oder zu verändern siehe GUICtrlUpdate....
Verwandte Funktionen
GUICtrlSetState, GUIGetMsg, GUICtrlCreateMenuItem, GUICtrlGetHandle, GUICtrlCreateContextMenu
Beispiel
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
Opt('MustDeclareVars', 1)
Example()
Func Example()
Local $defaultstatus = "Bereit", $status, $filemenu, $fileitem
Local $helpmenu, $saveitem, $infoitem, $exititem, $recentfilesmenu
Local $separator1, $viewmenu, $viewstatusitem, $okbutton, $cancelbutton
Local $statuslabel, $msg, $file
GUICreate("Mein GUI Menü", 300, 200)
$filemenu = GUICtrlCreateMenu("&Datei")
$fileitem = GUICtrlCreateMenuItem("Öffnen", $filemenu)
GUICtrlSetState(-1, $GUI_DEFBUTTON)
$helpmenu = GUICtrlCreateMenu("?")
$saveitem = GUICtrlCreateMenuItem("Speichern", $filemenu)
GUICtrlSetState(-1, $GUI_DISABLE)
$infoitem = GUICtrlCreateMenuItem("Info", $helpmenu)
$exititem = GUICtrlCreateMenuItem("Beenden", $filemenu)
$recentfilesmenu = GUICtrlCreateMenu("Letzte Dateien", $filemenu, 1)
$separator1 = GUICtrlCreateMenuItem("", $filemenu, 2) ; Erstellt eine Trennlinie (hier: leere Zeile)
$viewmenu = GUICtrlCreateMenu("Ansicht", -1, 1) ; Wird vor dem "?" Menü erstellt
$viewstatusitem = GUICtrlCreateMenuItem("Statusbar", $viewmenu)
GUICtrlSetState(-1, $GUI_CHECKED)
$okbutton = GUICtrlCreateButton("OK", 50, 130, 70, 20)
GUICtrlSetState(-1, $GUI_FOCUS)
$cancelbutton = GUICtrlCreateButton("Abbrechen", 180, 130, 70, 20)
$statuslabel = GUICtrlCreateLabel($defaultstatus, 0, 165, 300, 16, BitOR($SS_SIMPLE, $SS_SUNKEN))
GUISetState()
While 1
$msg = GUIGetMsg()
If $msg = $fileitem Then
$file = FileOpenDialog("Wählen Sie eine Datei aus...", @TempDir, "Alle (*.*)")
If @error <> 1 Then GUICtrlCreateMenuItem($file, $recentfilesmenu)
EndIf
If $msg = $viewstatusitem Then
If BitAND(GUICtrlRead($viewstatusitem), $GUI_CHECKED) = $GUI_CHECKED Then
GUICtrlSetState($viewstatusitem, $GUI_UNCHECKED)
GUICtrlSetState($statuslabel, $GUI_HIDE)
Else
GUICtrlSetState($viewstatusitem, $GUI_CHECKED)
GUICtrlSetState($statuslabel, $GUI_SHOW)
EndIf
EndIf
If $msg = $GUI_EVENT_CLOSE Or $msg = $cancelbutton Or $msg = $exititem Then ExitLoop
If $msg = $infoitem Then MsgBox(0, "Info", "Nur ein Test...")
WEnd
GUIDelete()
EndFunc ;==>Example