Funktionsreferenz

GUICtrlCreateTab

Erzeugt eine Karteireiterauswahl für die GUI.

GUICtrlCreateTab ( left, top [, width [, height [, style [, exStyle]]]] )

Parameter

left Die linke Seite des Controls. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet.
top Die Oberkante des Controls. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet.
width [optional] Die Breite des Controls (voreingestellt ist die zuvor verwendete Breite).
height [optional] Die Höhe des Controls (voreingestellt ist die zuvor verwendete Höhe).
style [optional] Legt den Stil des Controls fest. Siehe Anhang GUI-Stile für Controls.

Standard ( -1) : Keine.
Erzwungene Stile : $WS_TABSTOP
exStyle [optional] Legt den erweiterten Stil des Controls fest. Siehe Tabelle der erweiterten Stile.

Rückgabewert

Erfolg: Gibt die Identifikationsnummer (Control-ID) des neuen Controls zurück.
Fehler: Gibt 0 zurück.

Bemerkungen

Dieses Control ist einfach ein Control, in dem wiederum die TabItem-Controls erzeugt werden. Hinterher werden die zu einem spezifischen TabItem gehörenden Controls mit GUICtrlCreate... erzeugt.

Um Informationen im Control zu setzen oder zu verändern, siehe GUICtrlUpdate....

Um weitere Stile zusätzlich zum Standardstil zu verwenden, benutzt man BitOr($GUI_SS_DEFAULT_TAB, newstyle,...).

Um die oben angegebenen Werte verwenden zu können, muss #include <TabConstants.au3> in das Skript eingefügt werden.

Als Standard für das Verhalten des Controls (bzgl. Größe und/oder Position) bei Größenänderung der GUI gilt $GUI_DOCKSIZE. (Größe wird nicht geändert.)
Mögliche Resizing-Parameter siehe GUICtrlSetResizing.

Hinweis: Nur EIN Tab-Menü kann je GUI-Fenster erstellt werden. Aber ein Skript kann verschiedene Fenster mit je einem Kartenreiter-Menü darin erzeugen.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

GUICtrlCreateTabItem, GUICoordMode (Option), GUICtrlCreate..., GUICtrlUpdate..., GUIGetMsg

Beispiel


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $msg

    GUICreate("Meine GUI mit Tabs") ; Erstellt ein GUI-Fenster welches mittig ausgerichtet wird

    GUISetBkColor(0x00E0FFFF)
    GUISetFont(9, 300)

    GUICtrlCreateTab(10, 10, 200, 100)

    GUICtrlCreateTabItem("Tab0")
    GUICtrlCreateLabel("Beschriftung0", 30, 80, 80, 20)
    GUICtrlCreateButton("OK0", 20, 50, 50, 20)
    GUICtrlCreateInput("Standard", 80, 50, 70, 20)

    GUICtrlCreateTabItem("Tab----1")
    GUICtrlCreateLabel("Beschriftung1", 30, 80, 80, 20)
    GUICtrlCreateCombo("", 20, 50, 60, 120)
    GUICtrlSetData(-1, "Trids|CyberSlug|Larry|Jon|Tylo", "Jon") ; Standard Jon
    GUICtrlCreateButton("OK1", 80, 50, 50, 20)

    GUICtrlCreateTabItem("Tab2")
    GUICtrlSetState(-1, $GUI_SHOW) ; Lässt die GUI anzeigen
    GUICtrlCreateLabel("Beschriftung2", 30, 80, 80, 20)
    GUICtrlCreateButton("OK2", 140, 50, 50)

    GUICtrlCreateTabItem("") ; Beendet die Tab Definition

    GUICtrlCreateLabel("Beschriftung3", 20, 130, 80, 20)

    GUISetState()

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc   ;==>Example