Funktionsreferenz

GUICtrlCreateTabItem

Erstellt einen Tab für die GUI.

GUICtrlCreateTabItem ( "text" )

 

Parameter

text Der Text auf dem Tab.

 

Rückgabewert

Erfolg: Gibt die Identifikationsnummer (Control-ID) des neuen Controls zurück.
Fehler: Gibt 0 zurück.

 

Bemerkungen

Um weitere Informationen für das Control zu setzen siehe GUICtrlUpdate....

Um einen bestimmten Tab auszuwählen, die beim Öffnen der Dialogbox angezeigt wird, ist für diese Karte der Status GUICtrlSetState(-1,$GUI_SHOW) zu setzen (siehe Beispiel).

Um die Tabgruppe abzuschließen ist ein letztes "tabitem"-Control mit dem Text "" zu erstellen. Dieser Tab kann nicht angezeigt werden (zu viel Text ...)

Wenn der erweiterte Modus verwendet wird, wird GUICtrlRead($tab,1) die Control-ID anstatt dem Index des angeklickten Tabs zurückgeben.

Um ein neues Control auf einem bereits bestehenden Tab zu erstellen, ist GUISwitch($hWin,$tabitem) zu benutzen und es auszuwählen und auch um das neue Control zu erstellen.
Es sollte nicht vergessen werden, das die Erstellung des neuen Tabs mit GUICtrlCreateTabItem("") wieder beendet wird.

- - - - - - - - Erklärung der Controls - - - - - - - -

 

Verwandte Funktionen

GUICtrlSetState, GUISwitch, GUIGetMsg, GUICtrlRead, GUIEventOptions (Option), GUICtrlCreateTab

 

Beispiel


#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $tab, $tab0, $tab0OK, $tab0input
    Local $tab1, $tab1combo, $tab1OK
    Local $tab2, $tab2OK, $msg

    GUICreate("Meine GUI mit Tabs", 250, 175); Erstellt ein GUI-Fenster welches mittig ausgerichtet wird

    GUISetBkColor(0x00E0FFFF)
    GUISetFont(9, 300)

    $tab = GUICtrlCreateTab(10, 10, 200, 100)

    $tab0 = GUICtrlCreateTabItem("Tab0")
    GUICtrlCreateLabel("Beschriftung0", 30, 80, 80, 20)
    $tab0OK = GUICtrlCreateButton("OK0", 20, 50, 50, 20)
    $tab0input = GUICtrlCreateInput("Standard", 80, 50, 70, 20)

    $tab1 = GUICtrlCreateTabItem("Tab----1")
    GUICtrlCreateLabel("Beschriftung1", 30, 80, 80, 20)
    $tab1combo = GUICtrlCreateCombo("", 20, 50, 60, 120)
    GUICtrlSetData(-1, "Trids|CyberSlug|Larry|Jon|Tylo", "Jon") ; Standardwert Jon
    $tab1OK = GUICtrlCreateButton("OK1", 80, 50, 50, 20)

    $tab2 = GUICtrlCreateTabItem("Tab2")
    GUICtrlSetState(-1, $GUI_SHOW) ; Erscheint zuerst
    GUICtrlCreateLabel("Beschriftung2", 30, 80, 80, 20)
    $tab2OK = GUICtrlCreateButton("OK2", 140, 50, 50)

    GUICtrlCreateTabItem(""); Beendet die Tab Definition

    GUICtrlCreateLabel("Klicke auf einen Tab und dessen Beschriftung wird sichtbar", 20, 130, 250, 40)

    GUISetState()

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
        If $msg = $tab Then
            ; Der angeklickte Tab erscheint
            WinSetTitle("Meine GUI mit Tabs", "", "Meine GUI mit Tabs" & GUICtrlRead($tab))
        EndIf
    WEnd
EndFunc   ;==>Example