Funktionsreferenz

GUICtrlCreateTreeViewItem

Erstellt einen Eintrag in einem Treeview.

GUICtrlCreateTreeViewItem ( "text", treeviewID )

Parameter

text	Der Text des Controls.
treeviewID	Die Treeview-ID, die beim Erstellen eines Treeviews oder eines Treeview-Eintrags zurückgegeben wird; mit letzterer wird ein Sub-Treeview erzeugt.

Rückgabewert

Erfolg:	Gibt die Identifikationsnummer (Control-ID) des neuen Controls zurück.
Fehler:	Gibt 0 zurück.

Bemerkungen

Um weitere Informationen für das Control zu setzen siehe GUICtrlUpdate....

Um ein Treevieweintrag in dick darzustellen (als Standard angezeigen) ist GuiCtrlSetState($treeviewItem, $GUI_DEFBUTTON) zu benutzen.
Um den Standardeintrag wieder zurückzusetzen ist GUICtrlSetState() mit einem anderen Wert außer $GUI_DEFBUTTON zu benutzen.
Z. B. GuiCtrlSetState($treeviewItem, 0)

Um einen Treevieweintrag aufzuklappen ist GuiCtrlSetState($treeviewItem, $GUI_EXPAND) zu benutzen.

Um einen bestimmten Treevieweintrag auszuwählen ist GuiCtrlSetState($treeviewItem, $GUI_FOCUS) zu verwenden.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

GUICtrlCreateTreeView, GUICtrlUpdate..., GUIGetMsg, GUICtrlRead, GUICtrlGetHandle

Beispiel

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <TreeViewConstants.au3>
#include <StaticConstants.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
Local $treeview, $generalitem, $displayitem, $aboutitem, $compitem
Local $useritem, $resitem, $otheritem, $startlabel, $aboutlabel
Local $compinfo, $togglebutton, $infobutton, $statebutton, $cancelbutton
Local $msg, $item, $text, $hItem

GUICreate("Meine GUI mit Treeview", 350, 215)

$treeview = GUICtrlCreateTreeView(6, 6, 150, 150, BitOR($TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS), $WS_EX_CLIENTEDGE)
$generalitem = GUICtrlCreateTreeViewItem("Allgemein", $treeview)
GUICtrlSetColor(-1, 0x0000C0)
$displayitem = GUICtrlCreateTreeViewItem("Anzeige", $treeview)
GUICtrlSetColor(-1, 0x0000C0)
$aboutitem = GUICtrlCreateTreeViewItem("Über", $generalitem)
$compitem = GUICtrlCreateTreeViewItem("Computer", $generalitem)
$useritem = GUICtrlCreateTreeViewItem("Benutzer", $generalitem)
$resitem = GUICtrlCreateTreeViewItem("Auflösung", $displayitem)
$otheritem = GUICtrlCreateTreeViewItem("Sonstiges", $displayitem)

$startlabel = GUICtrlCreateLabel("Treeview Demo", 160, 90, 100, 20)
$aboutlabel = GUICtrlCreateLabel("Dieses kleine Skript demonstriert die Benutzung eines Treeview-Controls.", 160, 70, 150, 60)
GUICtrlSetState(-1, $GUI_HIDE) ; Versteckt den "aboutlabel"-Text während der Initialisierung
$compinfo = GUICtrlCreateLabel("Name:" & @TAB & @ComputerName & @LF & "OS:" & @TAB & @OSVersion & @LF & "SP:" & @TAB & @OSServicePack, 160, 30, 200, 80)
GUICtrlSetState(-1, $GUI_HIDE) ; Versteckt den "compinfo"-Text während der Initialisierung

GUICtrlCreateLabel("", 0, 170, 350, 2, $SS_SUNKEN)
$togglebutton = GUICtrlCreateButton("&Umschalten", 35, 185, 70, 20)
$infobutton = GUICtrlCreateButton("&Info", 105, 185, 70, 20)
$statebutton = GUICtrlCreateButton("Auf/Zu", 175, 185, 70, 20)
$cancelbutton = GUICtrlCreateButton("&Abbrechen", 245, 185, 70, 20)

GUICtrlSetState($generalitem, BitOR($GUI_EXPAND, $GUI_DEFBUTTON)) ; Expandiert den "Allgemein"-Tree und stellt ihn im Stil 'fett' dar
GUICtrlSetState($displayitem, BitOR($GUI_EXPAND, $GUI_DEFBUTTON)) ; Expandiert den "Anzeige"-Tree und stellt ihn im Stil 'fett' dar

GUISetState()
While 1
$msg = GUIGetMsg()
Select
Case $msg = $cancelbutton Or $msg = $GUI_EVENT_CLOSE
ExitLoop

Case $msg = $togglebutton ; Schriftstil 'fett ein/ausschalten
If BitAND(GUICtrlRead($generalitem), $GUI_DEFBUTTON) Then
GUICtrlSetState($generalitem, 0)
GUICtrlSetState($displayitem, 0)
Else
GUICtrlSetState($generalitem, $GUI_DEFBUTTON)
GUICtrlSetState($displayitem, $GUI_DEFBUTTON)
EndIf

Case $msg = $infobutton
$item = GUICtrlRead($treeview) ; Holt die Control-ID des aktuell gewählten Treeview-Items
If $item = 0 Then
MsgBox(64, "TreeviewDemo", "Momentan ist kein Eintrag markiert")
Else
$text = GUICtrlRead($item, 1) ; Holt den Text des Treeview-Items
If $text == "" Then
MsgBox(16, "Fehler", "Fehler während der Abfrage des Treeview-Items")
Else
MsgBox(64, "TreeviewDemo", "Aktuell gewähltes Item ist: " & $text) ; $advmsg[0] enthält den Text und $advmsg[1] den Statuswert des Treeview-Items
EndIf
EndIf

Case $msg = $statebutton ; Expandiert oder versteckt den markierten Tree
$item = GUICtrlRead($treeview)
If $item > 0 Then
$hItem = GUICtrlGetHandle($item)
DllCall("user32.dll", "int", "SendMessage", "hwnd", GUICtrlGetHandle($treeview), "int", $TVM_EXPAND, "int", $TVE_TOGGLE, "hwnd", $hItem)
EndIf

; Die folgenden Items verstecken die anderen Labels (erster und zweiter Parameter) und zeigen anschließend die 'eigenen' Labels (dritter und vierter Parameter)
Case $msg = $generalitem
GUIChangeItems($aboutlabel, $compinfo, $startlabel, $startlabel)

Case $msg = $aboutitem
GUICtrlSetState($compinfo, $GUI_HIDE)
GUIChangeItems($startlabel, $startlabel, $aboutlabel, $aboutlabel)

Case $msg = $compitem
GUIChangeItems($startlabel, $aboutlabel, $compinfo, $compinfo)
EndSelect
WEnd

GUIDelete()
EndFunc ;==>Example

Func GUIChangeItems($hidestart, $hideend, $showstart, $showend)
Local $idx

For $idx = $hidestart To $hideend
GUICtrlSetState($idx, $GUI_HIDE)
Next
For $idx = $showstart To $showend
GUICtrlSetState($idx, $GUI_SHOW)
Next
EndFunc ;==>GUIChangeItems