Funktionsreferenz

GUICtrlSetData

Verändert die Daten eines Controls.

GUICtrlSetData ( controlID, data [, default] )

Parameter

ControlID Die Identifikationsnummer des Controls (Control-ID), wie von einer GUICtrlCreate... Funktion zurückgegeben.
data Combo, List, ListView, ListViewItem: Ein Opt("GUIDataSeparatorChar",...) trennt die Items voneinander.
Progress: Prozentwert
Slider: Wert
Group, Label, Button, Checkbox, Radio, Combo, List, Input, Edit, TabItem, TreeViewItem: ersetzt den Text
Date: Das Datum oder die Uhrzeit, abhängig vom Stil des Controls und dem im PC eingestellten Format
Dummy: Der Wert
default [optional] Combo, List: der Standardwert.
Edit, Input: wenn ein Parameter angegeben wird und dieser nicht aus "" besteht, wird der String an der Cursorposition eingefügt

Rückgabewert

Erfolg: Gibt 1 zurück.
Fehler: Gibt 0 zurück.
Gibt -1 zurück, wenn die Daten ungültig sind

Bemerkungen

Für Combo oder List-Controls:
Wenn "data" mit einem bereits existierenden Eintrag übereinstimmt, wird dieser als Standard (default) verwendet.
Wenn "data" mit dem über GUIDataSeparatorChar definierten Zeichen beginnt oder einen leeren String ist (""), wird die vorherige Liste gelöscht.

Für ListView, ListViewItem Controls:
Um eine bestimmte Spalte zu verändern, wird für die anderen Spalten einfach "nichts" angegeben, z.B. verändert "||update" nur die dritte Spalte.

Falls "update" leer ist, wird die Spalte bzw. subitem gelöscht. Zum Beispiel wird "|" die zweite Spalte bzw. Subitem löschen, "" wird die erste Spalte löschen.

Für Monthcal Controls:
Das "data" Datumsformat lautet "yyyy/mm/dd".

Für Date controls:
Das Datum und die Zeit entsprechend dem im PC eingestellten Format. GuiCtrlRead() verwendet das gleiche Standardformat.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

GUICtrlCreate..., GUICtrlUpdate..., GUICtrlRead, GUIDataSeparatorChar (Option)

Beispiel


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $msg

    GUICreate("Meine GUI") ; Erstellt ein GUI-Fenster welches mittig ausgerichtet wird

    GUICtrlCreateCombo("", 10, 10)

    GUICtrlSetData(-1, "Eintrag1|Eintrag2|Eintrag3", "Eintrag3")

    GUISetState() ; Zeigt das leere GUI-Fenster mit einem Bezug auf das Combo-Control

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc   ;==>Example