Funktionsreferenz

GUICtrlSetFont

Setzt die Schriftart und Schriftgröße für ein Control.

GUICtrlSetFont ( controlID, size [, weight [, attribute [, fontname [, quality]]]] )

Parameter

ControlID Die Identifikationsnummer des Controls (Control-ID), wie von einer GUICtrlCreate... Funktion zurückgegeben.
size Schriftgröße (voreingestellt ist 8.5)
weight [optional] Schriftbreite (Standard 400 = normal)
attribute [optional] Definiert den Stil: 2-kursiv, 4-unterstrichen, 8-durchgestrichen (durch Addieren der Werte können mehrere Stile verwendet werden, 2+4 = kursiv und unterstrichen).
fontname [optional] Der Name der gewünschten Schriftart.
quality [optional] auszuwählende Qualität der Schrift (Standard ist PROOF_QUALITY=2).

Rückgabewert

Erfolg: Gibt 1 zurück.
Fehler: Gibt 0 zurück.

Bemerkungen

Standardmäßig wird für Controls die Schriftart verwendet, die durch GUISetFont festgelegt wurde.

Die Schriftgröße kann als Dezimalwert angegeben werden, wie z.B. 8.5.

Für manche Controls wie zum Beispiel Labels kann die Standardgröße 8.5 anstatt 9 sein, je nach dem aktuell verwendeten Windows-Stil.

Im Anhang ist eine komplette Liste der Schriftarten und der Betriebssysteme, die sie unterstützen, zu finden.

Für mehr Hilfe zum Parameter "Quality" siehe MSDN, manche Windows XP Installationen benötigen CLEARTYPE_QUALITY=5

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

GUICtrlCreate..., GUISetFont

Beispiel


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $font, $msg

    GUICreate("Meine GUI mit der Standard Schriftart") ; Erstellt ein GUI-Fenster welches mittig ausgerichtet wird

    $font = "Comic Sans MS"
    GUICtrlCreateLabel("unterstrichenes Label", 10, 20)
    GUICtrlSetFont(-1, 9, 400, 4, $font) ; Schrift wird unterstrichen

    GUICtrlCreateLabel("kursives Label", 10, 40)
    GUICtrlSetFont(-1, 9, 400, 2, $font) ; Schrift wird kursiv geschrieben

    GUISetFont(9, 400, 8, $font) ; Schrift wird durchgestrichen
    GUICtrlCreateLabel("durchgestrichenes Label", 10, 60)

    GUISetState() ; Zeigt das leere GUI-Fenster

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc   ;==>Example