Funktionsreferenz

GUICtrlSetResizing

Definiert die Methode zur Größenänderung, die von einem Control verwendet wird.

GUICtrlSetResizing ( controlID, resizing )

Parameter

ControlID Die Identifikationsnummer des Controls (Control-ID), wie von einer GUICtrlCreate... Funktion zurückgegeben.
resizing Siehe die untenstehende "Docking Values"-Tabelle, welche Werte verwendet werden können (falls nötig, werden mehrere Werte addiert).

Rückgabewert

Erfolg: Gibt 1 zurück.
Fehler: Gibt 0 zurück.

Bemerkungen

Wenn ein GUI-Fenster in seiner Größe verändert wird, reagieren die darin enthaltenen Controls auf die Änderung - Wie sie reagieren, wird durch diese Funktion bestimmt. Um ein GUI-Fenster in der Größe verändern zu können, muss es mit den Stilen $WS_SIZEBOX und $WS_SYSMENU erzeugt worden sein. Siehe GUICreate.

    "Docking Values"-Tabelle
Größenänderung Wert Keine Verschiebung ...
$GUI_DOCKAUTO 1 Größenänderung und Neupositionierung gemäß der neuen Fenstergröße
$GUI_DOCKLEFT 2 der linken Seite
$GUI_DOCKRIGHT 4 der rechten Seite
$GUI_DOCKHCENTER 8 Position wird nicht relativ zur horizontalen Mitte verändert
$GUI_DOCKTOP 32 der oberen Kante
$GUI_DOCKBOTTOM 64 der unteren Kante
$GUI_DOCKVCENTER 128 Position wird nicht relativ zur vertikalen Mitte verändert
$GUI_DOCKWIDTH 256 Breite wird nicht verändert
$GUI_DOCKHEIGHT 512 Höhe wird nicht verändert
gemischte Veränderung
$GUI_DOCKSIZE 768 (256+512) Größe wird nicht verändert
$GUI_DOCKMENUBAR 544 (512+32) das Control bleibt am oberen Rand des Fensters und ändert seine Höhe nicht.
$GUI_DOCKSTATEBAR 576 (512+64) das Control bleibt am unteren Rand des Fensters und ändert seine Höhe nicht.
$GUI_DOCKALL 802 (2+32+256+512) das Control verschiebt sich durch die Größenänderung nicht.
$GUI_DOCKBORDERS 102 (2+4+32+64) das Control wächst ebenso wie das Fenster

Die Standard-Größenänderung für ein Control ist Controlabhängig (siehe Control-Dokumentation).
Ein Standardwert für jedes Control kann mit GUIResizeMode (Option) gesetzt werden.

Die automatische Größenänderung kann deaktiviert werden, indem man GUIEventOptions (Option) auf 1 setzt.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

GUIResizeMode (Option), GUIEventOptions (Option), GUICtrlCreate...

Beispiel


#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

Example()

Func Example()
    Local $nEdit, $nOk, $nCancel, $msg

    Opt("GUICoordMode", 2)
    GUICreate("Meine InputBox", 190, 114, -1, -1, $WS_SIZEBOX + $WS_SYSMENU) ; Lege Stil fest
    GUISetIcon("Eiffel Tower.ico")

    GUISetFont(8, -1, "Arial")

    GUICtrlCreateLabel("Eingabeaufforderung", 8, 7) ; Fügt Info hinzu
    GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKTOP)

    $nEdit = GUICtrlCreateInput("Standard", -1, 3, 175, 20, $ES_PASSWORD) ; Fügt das Input-Control hinzu
    GUICtrlSetState($nEdit, $GUI_FOCUS)
    GUICtrlSetResizing($nEdit, $GUI_DOCKBOTTOM + $GUI_DOCKHEIGHT)

    $nOk = GUICtrlCreateButton("OK", -1, 3, 75, 24) ; Fügt den Button hinzu, der die GUI schliesst
    GUICtrlSetResizing($nOk, $GUI_DOCKBOTTOM + $GUI_DOCKSIZE + $GUI_DOCKHCENTER)

    $nCancel = GUICtrlCreateButton("Abbrechen", 25, -1) ; Fügt den Button hinzu, der die GUI schliesst
    GUICtrlSetResizing($nCancel, $GUI_DOCKBOTTOM + $GUI_DOCKSIZE + $GUI_DOCKHCENTER)

    GUISetState() ; Um die GUI anzuzeigen

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc   ;==>Example