Funktionsreferenz

GUIGetStyle

Erfragt den Stil GUI-Fensters.

GUIGetStyle ( [winhandle] )

Parameter

winhandle [optional] Fensterhandle der aus GUICreate zurückgegeben wird (Standard ist das zuvor genutzte Fenster).

Rückgabewert

Erfolg: Gibt ein Zwei-Item Array zurück das die Stil-Information enthält:
$array[0] = Stil
$array[1] = Erweiterter Stil
Fehler: Gibt 0 zurück.

Bemerkungen

Es ist zu Beachten: Der Stil wechselt nach einem Aufruf von GUISetState().

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

GUICreate, GUISetStyle

Beispiel


#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $NewStyle = False, $hWnd, $Style, $GuiStyles, $Msg

    $hWnd = GUICreate("GUI Stil", 260, 100)
    $Style = GUICtrlCreateButton("Setzt den Stil", 45, 50, 150, 20)

    $GuiStyles = GUIGetStyle($hWnd) ; Vorsicht: Der Status ändert sich nach dem Ausführen von GUISetState()

    GUISetState()


    While 1
        $Msg = GUIGetMsg()
        Switch $Msg
            Case $GUI_EVENT_CLOSE
                Exit
            Case $Style
                If Not $NewStyle Then
                    GUISetStyle($WS_POPUPWINDOW + $WS_THICKFRAME, $WS_EX_CLIENTEDGE + $WS_EX_TOOLWINDOW)
                    GUICtrlSetData($Style, 'Stil zurücksetzen')
                    $NewStyle = True
                Else
                    GUISetStyle($GuiStyles[0], $GuiStyles[1])
                    GUICtrlSetData($Style, 'Setzt den Stil')
                    $NewStyle = False
                EndIf
            Case Else
        EndSwitch
    WEnd
EndFunc   ;==>Example