Funktionsreferenz

GUISetAccelerators

Setzt eine Tabelle mit Zugriffstasten in einem GUI Fenster.

GUISetAccelerators ( accelerators [, winhandle] )

 

Parameter

accelerators Ein 2-dimensionales Array mit der Tabelle mit Zugriffstasten (Siehe Bemerkungen).
winhandle [optional] Fenster-Handle, welches von GUICreate zurückgegeben wurde (Standard ist das zuvor verwendete Fenster).

 

Rückgabewert

Erfolg: Gibt 1 zurück.
Fehler: Gibt 0 zurück.

 

Bemerkungen

Das Array enthält die Zugriffstasten und die Control-ID. Das Array muss als Dim $array[n][2] deklariert werden - wobei n die Anzahl von zu setzenden Zugriffstasten ist:

$array[0][0] = Zugriffstaste (im HotKeySet()-Format) der ersten Taste
$array[0][1] = Control-ID der ersten Taste, welche durch GUICtrlCreate...() zurückgegeben wurde
$array[1][0] = Zugriffstaste der zweiten Taste
$array[1][1] = Control-ID der zweiten Taste
...
$array[n][0] = Zugriffstaste der nten Taste
$array[n][1] = Control-ID der nten Taste

Falls dieser Funktion kein gültiges Array übergeben wird, werden alle Tasten für das angegebene Fensterhandle zurückgesetzt.

- - - - - - - - Erklärung der Controls - - - - - - - -

 

Verwandte Funktionen

GUICreate, HotKeySet

 

Beispiel


; Eine einfache benutzerdefinierte Nachrichtenbox, welche den MessageLoop-Modus verwendet

#include <GUIConstantsEx.au3>

GUICreate("Benutzerdefinierte Msgbox", 270, 80)

GUICtrlCreateLabel("Bitte klicke einen Button an!", 70, 10)
$YesID = GUICtrlCreateButton("Ja", 40, 50, 50, 20)
$NoID = GUICtrlCreateButton("Nein", 110, 50, 50, 20)
$ExitID = GUICtrlCreateButton("Beenden", 180, 50, 50, 20)

; Weist bestimmten Buttons Schnellzugriffstasten zu (für Strg+y und Strg+n)
Dim $AccelKeys[2][2] = [["^y", $YesID],["^n", $NoID]]
GUISetAccelerators($AccelKeys)

GUISetState() ; Zeigt die GUI an

Do
    $msg = GUIGetMsg()

    Select
        Case $msg = $YesID
            MsgBox(0, "Betätigter Button", "Ja")
        Case $msg = $NoID
            MsgBox(0, "Betätigter Button", "Nein")
        Case $msg = $ExitID
            MsgBox(0, "Betätigter Button", "Beenden")
        Case $msg = $GUI_EVENT_CLOSE
            MsgBox(0, "Betätigter Button", "Schließen")
    EndSelect
Until $msg = $GUI_EVENT_CLOSE Or $msg = $ExitID