Funktionsreferenz

HWnd

Wandelt einen Ausdruck in ein HWND Handle.

HWnd ( expression )

Parameter

expression Der Ausdruck, der in ein HWND Handle konvertiert werden soll.

Rückgabewert

Erfolg: Wenn der Ausdruck in ein HWND konvertiert werden kann, wird dieser zurückgegeben.
Fehler: Falls kein Fenster mit diesem HWND existiert, wird ein 0 (NULL) HWND zurückgegeben und @error auf 1 gesetzt.

Bemerkungen

Doppelzahlen können nicht in einen HWND konvertiert werden. Zudem sollte kein nur Buchstaben enthaltener String in einen HWND gewandelt werden, da es keine Garantie gibt, dass ein Fenster jemals wieder den selben HWND hat. Es ist zwar nicht verboten, stellt aber einen Programmierfehler dar, der vermieden werden sollte.

Verwandte Funktionen

Int, String, Number, Ptr

Beispiel


Example()

Func Example()
    ; Startet Notepad
    Run("notepad.exe")

    ; Wartet maximal 10 Sekunden bis das Notepad-Fenster erscheint.
    Local $hWnd = WinWait("[CLASS:Notepad]", "", 10)

    ; Konvertiert das Handle in einen String.
    Local $sHWnd = String($hWnd)

    ; Minimiert das Notepad-Fenster und wartet 2 Sekunden.
    WinSetState(HWnd($sHWnd), "", @SW_MINIMIZE)
    Sleep(2000)

    ; Macht eine Fensterminimierung des Notepad-Fensters wieder rückgängig und wartet 2 Sekunden.
    WinSetState(HWnd($sHWnd), "", @SW_RESTORE)
    Sleep(2000)

    WinClose(HWnd($sHWnd)) ; Schließt das Notepad-Fenster.
EndFunc   ;==>Example