Funktionsreferenz

InputBox

Zeigt eine Eingabe-Box und fordert den Benutzer auf, ein String einzugeben.

InputBox ( "title", "prompt" [, "default" [, "password char" [, width [, height [, left [, top [, timeout [, hwnd]]]]]]]] )

Parameter

title Der Titel der Eingabe-Box.
prompt Eine Nachricht für den Benutzer, die beschreibt, was für eine Eingabe erwartet wird.
default [optional] Der in der Eingabe-Box vorgegebene Wert.
password char [optional] Das Zeichen, mit dem alle eingegebenen Zeichen ersetzt werden sollen. Wenn die gerade getippten Zeichen angezeigt werden sollen, ist ein Leerstring ("") anzugeben (Standard) oder ein Leerzeichen als erstes Zeichen. Stellt man ein String mit mehreren Zeichen zur Verfügung, wird nur das erste Zeichen zur Maskierung benutzt. Es existieren spezielle Bedeutungen für das zweite und die folgenden Zeichen. Siehe Bemerkungen.
width [optional] Die Breite des Fensters.
height [optional] Die Höhe des Fensters.
left [optional] Der linke Rand der Eingabe-Box. Standardmäßig wird die Box zentriert angezeigt.
top [optional] Der obere Rand der Eingabe-Box. Standardmäßig wird die Box zentriert angezeigt.
timeout [optional] Gibt die Wartezeit in Sekunden an, bevor die Eingabe-Box automatisch geschlossen wird.
hwnd [optional] Das Fenster Handle welches als Parent für diesen Dialog verwendet werden soll.

Rückgabewert

Erfolg: Gibt den eingegebenen String zurück.
Fehler: Gibt einen Leerstring "" zurück und setzt @error wie folgt:
@Error 0 = Der zurückgegebene String ist gültig.
1 = Der Abbrechen-Button wurde gedrückt.
2 = Die Timeout Wartezeit wurde erreicht.
3 = Die Eingabe-Box konnte nicht dargestellt werden. Dies passiert normalerweise durch fehlerhafte Argumente.
4 = Die Eingabe-Box konnte nicht auf jedem Monitor dargestellt werden.
5 = Ungültige Parameter. Breite ohne Höhe oder Linke Seite ohne obere Seite.

Bemerkungen

Die Eingabe-Box kann vom Benutzer in der Größe verändert werden, hat aber eine Minimalgröße von etwa 190 x 115 Pixel. Die Standardgröße beträgt etwa 250 x 190 Pixel.

Der zurückgegebene String kann eine Länge von max. 254 Zeichen nicht überschreiten. Wenn die Eingabe "carriage returns" oder "linefeeds" enthält, wird das Ergebnis beim ersten Auftreten eines solchen Zeichens abgeschnitten.

Das zweite und die folgenden Zeichen des Passwortfeldes können genutzt werden, um Eingaben einzuschränken. Ein Leerzeichen als erstes Zeichen lässt die Anzeige der eingetippten Zeichen zu. Ein gesetztes M nach dem ersten Zeichen zeigt an, dass die Eingabe ein Muss ist; d.h. eine Eingabe ist zwingend erforderlich. Wurde keine Eingabe getätigt und der Ok Button gedrückt, passiert nichts. Die Eingabe-Box bleibt geöffnet.

Man kann auch die maximale Länge am Ende des Passwortfeldes angeben. Dazu gibt man einfach als letztes Zeichen die entsprechende Zahl an.

Verwandte Funktionen

MsgBox

Beispiel


; Platziert die Eingabebox oben links in der Ecke und zeigt die Zeichen an so wie sie eingegeben werden

Local $answer = InputBox("Frage", "Wo wurdest du geboren?", "Planet Erde", "", _
         -1, -1, 0, 0)

; Bittet den Benutzer ein Passwort einzugeben.
; Nicht vergessen es mit Sternchen anzeigen zu lassen!
Local $passwd = InputBox("Sicherheitscheck", "Bitte geben Sie ein Passwort ein.", "", "*")

;
; Erwartet vom Benutzer eine Eingabe von einem oder zwei Zeichen.
; Das M im Passwortfeld bedeutet, dass eine leere Eingabe nicht angenommen wird.
; Die 2 zeigt, dass maximal zwei Zeichen eingegeben werden dürfen
Local $value = InputBox("Test", "Bitte geben Sie ein oder zwei Zeichen ein.", "", " M2")