Funktionsreferenz

ObjName

Gibt den Namen oder die Schnittstelleninformation eines Objekts zurück

ObjName ( $Objectvariable [,Flag] )

Parameter

$Objectvariable Eine Variable die das Objekt enthält dessen Namen man abrufen möchte
Flag [optional] 1 = Name der Dispatch-Schnittstelle die genutzt wird (Standard)
2 = Beschreibung des (Dokument) Objekts
3 = Die ProgID des Objekts
4 = Die DLL-Datei von der das Objekt erstellt wurde (wenn unterstützt)
5 = Dateiname und Position des Toolbox-Icons (wenn unterstützt)

Rückgabewert

Erfolg: Gibt einen den Namen repräsentierenden String zurück
Fehler: Setzt @error und gibt "" zurück

Bemerkungen

Nicht alle Objekte unterstützen die Flags (Bitschalter) 2 bis 5. Stets in diesen Fällen @error abfragen.

Verwandte Funktionen

IsObj, ObjGet, ObjCreate

Beispiel


Local $oInternet = ObjCreate("InternetExplorer.Application")
$oInternet.Navigate("http://www.google.com") ; Öffnet eine Webseite, die ein Formular beinhaltet
Sleep(4000) ; Gibt der Seite Zeit zu laden

Local $oDoc = $oInternet.document ; Zu testendes Beispielobjekt
Local $oForm = $oDoc.forms(0) ; Zu testendes Beispielobjekt

MsgBox(0, "", "Interface-Name von $oInternet ist: " & ObjName($oInternet) & @CRLF & _
        "Objekt-Name von $oInternet ist:    " & ObjName($oInternet, 2) & @CRLF & _
        "Interface-Name von $oDoc ist:      " & ObjName($oDoc) & @CRLF & _
        "Objekt-Name von $oDoc ist:         " & ObjName($oDoc, 2) & @CRLF & _
        "Interface-Name von $oForm ist:     " & ObjName($oForm) & @CRLF & _
        "Objekt-Name von $oForm ist:        " & ObjName($oForm, 2))