Funktionsreferenz

TrayItemSetOnEvent

Legt die Funktion (UDF) fest, die aufgerufen wird, wenn ein TrayItem angeklickt wird.

TrayItemSetOnEvent ( itemID, "function" )

Parameter

itemID	Die ID des Items, wie sie die Funktion TrayCreateItem zurückgibt.
function	Der Name der User-Funktion, die aufgerufen werden soll.

Rückgabewert

Erfolg:	Gibt 1 zurück.
Fehler:	Gibt 0 zurück.
@error:	1 falls "function" nicht definiert ist.

Bemerkungen

Die OnEvent-Funktionen werden nur aufgerufen, wenn die Option TrayOnEventMode auf 1 gesetzt ist. In diesem Zustand wird TrayGetMsg überhaupt nicht verwendet.

In der aufgerufenen User-Funktion erhält man mit dem Makro @TRAY_ID die ID des geklickten Items.

Ein Aufruf mit einem leeren String ("") bewirkt, dass die zuvor auf das Item gesetzte Funktion deaktiviert wird.

Verwandte Funktionen

TrayCreateItem, TrayGetMsg, TrayOnEventMode (Option), TraySetOnEvent

Beispiel

#NoTrayIcon

Opt("TrayOnEventMode",1)
Opt("TrayMenuMode",1) ; Standard Traymenüeinträge (Skript pausieren/beenden) werden nicht angezeigt.

TraySetClick(16) ; Nur wenn die zweite Maustaste gedrückt wird, wird das Traymenü anzeigt.

$infoitem = TrayCreateItem("Info")
TrayItemSetOnEvent(-1,"ShowInfo")

TrayCreateItem("")

$exititem = TrayCreateItem("Beenden")
TrayItemSetOnEvent(-1,"ExitScript")

TraySetState()

While 1
Sleep(10) ; CPU-Last verhindern
WEnd

Exit

; Funktionen
Func ShowInfo()
Msgbox(0,"Info","Tray OnEvent Demo")
EndFunc

Func ExitScript()
Exit
EndFunc