Sortiert ein 1-dimensionales oder 2-dimensionales Array durch einen festgelegten Index. Dabei werden Quicksort- und Insertionsort-Algorithmen verwendet.
#include <Array.au3>
_ArraySort(ByRef $avArray [, $iDescending = 0 [, $iStart = 0 [, $iEnd = 0 [, $iSubItem = 0]]]])
| $avArray | Array, das sortiert werden soll. |
| $iDescending | [optional] Falls auf 1 gesetzt wird absteigend sortiert. |
| $iStart | [optional] Start-Index für die Sortierung |
| $iEnd | [optional] Stopp-Index für die Sortierung |
| $iSubItem | [optional] Sub-Index der in einem 2-dimensionalen Array sortiert werden soll |
| Erfolg: | 1 |
| Fehler: | 0, setzt @error: |
| @error: | 1 - $avArray ist kein Array |
| 2 - $iStart ist größer als $iEnd | |
| 3 - $iSubItem ist größer als die Anzahl der Subitems | |
| 4 - $avArray hat zu viele Dimensionen |
#include <Array.au3>
;===============================================================================
; Beispiel 1 (verwendet ein 1D Array)
;===============================================================================
Local $avArray[10] = [9, 8, 7, 6, 5, 4, 3, 2, 1, 0]
_ArrayDisplay($avArray, "$avArray VOR _ArraySort()")
_ArraySort($avArray)
_ArrayDisplay($avArray, "$avArray NACHDEM _ArraySort() aufsteigend sortiert hat")
_ArraySort($avArray, 1)
_ArrayDisplay($avArray, "$avArray NACHDEM _ArraySort() absteigend sortiert hat")
_ArraySort($avArray, 0, 3, 6)
_ArrayDisplay($avArray, "$avArray NACHDEM _ArraySort() aufsteigend von Index 3 bis 6 sortiert hat")
;===============================================================================
; Beispiel 2 (verwendet ein 2D Array)
;===============================================================================
Local $avArray[5][3] = [ _
[5, 20, 8], _
[4, 32, 7], _
[3, 16, 9], _
[2, 35, 0], _
[1, 19, 6]]
_ArrayDisplay($avArray, "$avArray VOR _ArraySort()")
_ArraySort($avArray, 0, 0, 0, 0)
_ArrayDisplay($avArray, "$avArray NACHDEM _ArraySort() Spalte 0 aufsteigend sortiert hat")
_ArraySort($avArray, 0, 0, 0, 1)
_ArrayDisplay($avArray, "$avArray NACHDEM _ArraySort() Spalte 1 aufsteigend sortiert hat")
_ArraySort($avArray, 0, 0, 0, 2)
_ArrayDisplay($avArray, "$avArray NACHDEM _ArraySort() Spalte 2 aufsteigend sortiert hat")