Zählt die Datenformate auf, die aktuell in der Zwischenablage vorhanden sind.
#Include <Clipboard.au3>
_ClipBoard_EnumFormats($iFormat)
Parameter
| $iFormat | Gibt ein Zwischenablagen-Format an, das sicher vorhanden ist. Um eine Aufzählung zu beginnen, ist $iFormat auf Null zu setzen. Wenn $iFormat Null ist, gibt die Funktion das erste verfügbare Zwischenablagen-Format zurück. Bei weiteren Aufrufen während der Aufzählung muss $iFormat den Rückgabewert des vorigen Aufrufs erhalten. |
Rückgabewert
| Erfolg: | Das Zwischenablagen-Format, das auf das angegebene folgt. |
| Fehler: | 0 |
Bemerkungen
Die Zwischenablage muss geöffnet worden sein, bevor die Aufzählung durchgeführt werden kann
Verwandte Funktionen
_ClipBoard_Open, _ClipBoard_CountFormats, _ClipBoard_GetPriorityFormat, _ClipBoard_RegisterFormat
Siehe auch
Suche in der MSDN Bibliothek nach EnumClipboardFormats
Beispiel
#include <GuiConstantsEx.au3>
#include <ClipBoard.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $iFormat, $iCount
; Erstellt eine GUI
$hGUI = GUICreate("Zwischenablage", 600, 400)
$iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; Öffnet die Zwischenablage
If Not _ClipBoard_Open ($hGUI) Then _WinAPI_ShowError ("_ClipBoard_Open fehlgeschlagen!")
; Liest die Anzahl der verschiedenen Datenformate aus, die in der Zwischenablage verfügbar sind
MemoWrite("Clipboard-Formate ..: " & _ClipBoard_CountFormats ())
; Auflisten der Clipboard-Formate
Do
$iFormat = _ClipBoard_EnumFormats ($iFormat)
If $iFormat <> 0 Then
$iCount += 1
MemoWrite("Clipboard-Format " & $iCount & " .: " & _ClipBoard_FormatStr ($iFormat))
EndIf
Until $iFormat = 0
; Schließt die Zwischenablage
_ClipBoard_Close ()
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite