Gibt das Handle des Fensters zurück, das gerade die Zwischenablage geöffnet hat.
#Include <Clipboard.au3>
_ClipBoard_GetOpenWindow()
Parameter
Keine.
Rückgabewert
| Erfolg: | Das Handle des Fensters, das gerade die Zwischenablage geöffnet hat |
| Fehler: | Null, falls kein Fenster die Zwischenablage geöffnet hat |
Bemerkungen
Falls eine Applikation oder DLL beim Aufruf der Funktion _ClipBoard_Open das Handle eines "NULL-Fensters" spezifiziert, wird zwar die Zwischenablage geöffnet, sie ist aber mit keinem Fenster verbunden. In so einem Fall gibt _ClipBoard_GetOpenWindow 0 zurück.
Verwandte Funktionen
_ClipBoard_GetOwner, _ClipBoard_Open
Siehe auch
Suche in der MSDN Bibliothek nach GetOpenClipboardWindow
Beispiel
#include <GuiConstantsEx.au3>
#include <ClipBoard.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
Global $iMemo
_Main()
Func _Main()
Local $hGUI
; Erstellt eine GUI
$hGUI = GUICreate("Zwischenablage", 600, 400)
$iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; Öffnet die Zwischenablage
If Not _ClipBoard_Open($hGUI) Then _WinAPI_ShowError("_ClipBoard_Open fehlgeschlagen!")
ShowData($hGUI)
; Schließt die Zwischenablage
_ClipBoard_Close()
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; Zeige Informationen über die Zwischenablage
Func ShowData($hGUI)
MemoWrite("GUI Handle ...............: " & $hGUI)
MemoWrite("Clipboard Besitzer .......: " & _ClipBoard_GetOwner())
MemoWrite("Clipboard Fenster offen ..: " & _ClipBoard_GetOpenWindow())
MemoWrite("Clipboard Sequenz-Nr. ....: " & _ClipBoard_GetSequenceNumber())
MemoWrite()
EndFunc ;==>ShowData
; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite