Verschlüsselt Daten mit dem gegebenen Schlüssel
#Include <Crypt.au3>
_Crypt_EncryptData($vData, $vCryptKey, $iALG_ID[, $fFinal = True])
Parameter
| $vData | Daten die verschlüsselt werden sollen |
| $vCryptKey | Passwort oder Handle zu einem Schlüssel, wenn das CALG_USERKEY Flag angegeben ist. |
| $iALG_ID | Der zu benutzende Algorythmus |
| $fFinal | [optional] False, wenn dies nur ein Teil der gesamten Daten ist. |
Rückgabewert
| Erfolg | Gibt die verschlüsselten Daten zurück. |
| Setzt @error auf 0 | |
| Fehler | Gibt -1 zurück und setzt @error: |
| 1 - Schlüssel konnte nicht erstellt werden | |
| 2 - Puffer konnte nicht bestimmt werden | |
| 3 - Daten konnten nicht verschlüsselt werden |
Bemerkungen
Gibt einen Binär-String zurück, unabhängig von den eingegebenen Daten
Verwandte Funktionen
_Crypt_DecryptData, _Crypt_DeriveKey, _Crypt_EncryptFile
Siehe auch
Suche in der MSDN Bibliothek nach CryptEncrypt
Beispiel
#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>
#include <Crypt.au3>
#include <WinAPI.au3>
; Beispiel für eine RC4-Verschlüsselung in Echtzeit
$hWnd=GUICreate("Echzeit Verschlüsselung",400,300,-1)
$hInputEdit=GUICtrlCreateEdit("",0,0,400,150,$ES_WANTRETURN)
$hOutputEdit=GUICtrlCreateEdit("",0,150,400,150,$ES_READONLY)
GUIRegisterMsg($WM_COMMAND,"WM_COMMAND")
GUISetState(@SW_SHOW)
; Um die Performance zu verbessern starten wir die Crypt-Library und erstellen einen Schlüssel
_Crypt_Startup()
$hKey=_Crypt_DeriveKey("EinPasswort",$CALG_RC4)
Do
$msg=GUIGetMsg()
Until $msg=$GUI_EVENT_close
_Crypt_DestroyKey($hKey)
_Crypt_Shutdown()
Func WM_COMMAND($hWinHandle,$iMsg,$wParam,$lParam)
; Wenn sich etwas in der InputBox ändert
If _WinAPI_HiWord($wParam)=$EN_CHANGE And _WINAPI_LoWord($wParam)=$hInputEdit Then
$bEncrypted=_Crypt_EncryptData(GUICtrlRead($hInputEdit),$hKey,$CALG_USERKEY)
GUICtrlSetData($hOutputEdit,$bEncrypted)
EndIf
EndFunc