Funktionsreferenz

_Date_Time_FileTimeToDOSDateTime

Konvertiert Datei Datum/Zeit in MS-DOS Datum/Zeit

#Include <Date.au3>
_Date_Time_FileTimeToDOSDateTime($pFileTime)

 

Parameter

$pFileTime Zeiger auf eine $tagFILETIME Struktur, die ein Datei-Datum/Zeit beinhaltet, die ins MS-DOS Format konvertiert werden soll

 

Rückgabewert

Gibt ein Array mit dem folgenden Format zurück:
    [0] - MS-DOS Datum, verpackt wie folgt:
    Bits 0- 4 Tag des Monats (1–31)
    Bits 5- 8 Monat (1 = Januar, 2 = Februar und so weiter)
    Bits 9-15 Offset des Jahres von 1980 aus gesehen (es ist 1980 hinzuzuaddieren, um das aktuelle Jahr zu bekommen)
    [1] - MS-DOS Zeit, verpackt wie folgt:
    Bits 0- 4 Sekunden zweigeteilt
    Bits 5-10 Minuten (0–59)
    Bits 11-15 Stunden (0–23 im 24h-Format)

 

Bemerkungen

Keine.

 

Verwandte Funktionen

_Date_Time_FileTimeToLocalFileTime, _Date_Time_FileTimeToSystemTime, _Date_Time_DOSDateTimeToFileTime, $tagFILETIME

 

Beispiel


#include <GuiConstantsEx.au3>
#include <Date.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $tFile, $aDOS

    ; Erstellen der GUI
    $hGUI = GUICreate("Zeit", 400, 300)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Entschlüsseln der Datei Zeit
    $tFile = _Date_Time_EncodeFileTime(@MON, @MDAY, @YEAR, @HOUR, @MIN, @SEC)
    $aDOS = _Date_Time_FileTimeToDOSDateTime(DllStructGetPtr($tFile))
    MemoWrite("DOS date .: 0x" & Hex($aDOS[0], 4))
    MemoWrite("DOS time .: 0x" & Hex($aDOS[1], 4))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Schreibt eine Zeile in das Memo Control
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite