Funktionsreferenz

_Date_Time_GetSystemTimeAdjustment

Gibt an, ob das System periodisch eine Anpassung der Uhrzeit vornimmt

#Include <Date.au3>
_Date_Time_GetSystemTimeAdjustment()

 

Parameter

Keine.

 

Rückgabewert

Gibt ein Array mit dem folgenden Format zurück:
    [1] - Die Anzahl an 100 Nanosekunden Einheiten, die bei jeder periodischen Anpassung der Uhrzeit addiert wurden
    [2] - Die Anzahl an 100 Nanosekunden Einheiten zwischen den periodischen Zeitanpassungen. Dieses Intervall ist die Zeitdauer zwischen einem Systemzeit Interrupt.
    [3] - True gibt an, dass periodische Zeitanpassung deaktiviert ist. Bei jedem Zeit Interrupt wird lediglich die Zeitdifferenz des Interrupt's addiert. False gibt an, dass die periodische Zeitanpassung aktiviert ist.

 

Bemerkungen

Keine.

 

Verwandte Funktionen

_Date_Time_SetSystemTimeAdjustment

 

Beispiel


#include <Date.au3>
#include <WinAPI.au3>

; Unter Vista muß die Windows API "SetSystemTimeAdjustment" möglicherweise von der Systemsicherheit ausgenommen werden

_Main()

Func _Main()
    Local $aInfo

    ; Öffnen des Zeitdialogs, um die Änderungen zu verfolgen ;)
    Run("RunDll32.exe shell32.dll,Control_RunDLL timedate.cpl")
    WinWaitActive("[CLASS:#32770]")

    ; Ermittelt die aktuellen Zeiteinstellungen
    $aInfo = _Date_Time_GetSystemTimeAdjustment()

    ; Verlangsame die Systemuhr
    If Not _Date_Time_SetSystemTimeAdjustment($aInfo[1] / 10, False) Then
        MsgBox(4096, "Fehler", "Die Systemzeit kann nicht gebremst werden" & @CRLF & @CRLF & _WinAPI_GetLastErrorMessage())
        Exit
    EndIf
    MsgBox(4096, "Information", "Bremse die Zeit", 2)
    Sleep(5000)

    ; Beschleunige die Zeit
    If Not _Date_Time_SetSystemTimeAdjustment($aInfo[1] * 10, False) Then
        MsgBox(4096, "Fehler", "Die Systemzeit kann nicht beschleunigt werden" & @CRLF & @CRLF & _WinAPI_GetLastErrorMessage())
    EndIf
    MsgBox(4096, "Information", "Gib Gas", 2)

    Sleep(5000)

    ; Rücksetzen der Zeiteinstellungen
    If Not _Date_Time_SetSystemTimeAdjustment($aInfo[1], True) Then
        MsgBox(4096, "Fehler", "Die Systemzeit kann nicht wiederhergestellt werden" & @CRLF & @CRLF & _WinAPI_GetLastErrorMessage())
    Else
        MsgBox(4096, "Information", "Systemzeit wiederhergestellt")
    EndIf

EndFunc   ;==>_Main