Öffnet ein Handle zu einem Backup Event Log
#Include <EventLog.au3>
_EventLog__OpenBackup($sServerName, $sFileName)
Parameter
| $sServerName | Der UNC-Name des Servers, auf dem das Event Log geöffnet werden soll. Ohne Angabe eines Namens wird auf dem lokalen Computer die Operation ausgeführt. |
| $sFileName | Der Name der Backup Datei |
Rückgabewert
| Erfolg: | Das Handle zum Event Log Backup |
| Fehler: | 0 |
Bemerkungen
Wenn im Backup Namen der Backup Datei die Pfadangabe zu einem Server bereits angegeben ist, so muss $sServerName leer bleiben
Verwandte Funktionen
_EventLog__Close, _EventLog__Backup
Beispiel
#include <GuiConstantsEx.au3>
#include <EventLog.au3>
Global $iMemo
_Main()
Func _Main()
Local $hEventLog, $hGUI
; Erstellt das GUI
$hGUI = GUICreate("EventLog", 400, 300)
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 300, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
$hEventLog = _EventLog__Open("", "Application")
_EventLog__Backup($hEventLog, "C:\EventLog.bak")
_EventLog__Close($hEventLog)
$hEventLog = _EventLog__OpenBackup("", "C:\EventLog.bak")
MemoWrite("Log komplett ..........: " & _EventLog__Full($hEventLog))
MemoWrite("Log Anzahl Aufnahmen...: " & _EventLog__Count($hEventLog))
MemoWrite("Log ältester Datensatz : " & _EventLog__Oldest($hEventLog))
_EventLog__Close($hEventLog)
; Die Schleife wiederholt sich, bis der Benutzer das Fenster schließt
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; Gibt eine Zeile im Memo- Fenster aus
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite