Fügt ein Anzahl von Spalten in die aktuelle Excel-Datei ein.
#Include <Excel.au3>
_ExcelColumnInsert($oExcel, $iColumn [, $iNumCols = 1])
Parameter
| $oExcel | Ein Excel Objekt welches durch einen vorherigen Aufruf von _ExcelBookOpen() oder _ExcelBookNew() geöffnet wurde |
| $iColumn | Die Spaltenposition für das einfügen |
| $iNumCols | [optional] Die Anzahl der einzufügenden Spalten |
Rückgabewert
| Erfolg: | Gibt 1 zurück |
| Fehler: | Gibt 0 zurück und setzt @error |
| @error: | 1 - festgelegtes Objekt existiert nicht |
| 2 - festgelegtes Spalte ist ungültig |
Bemerkungen
Diese Funktion wird alle Spalten die sich nach der eingefügten Spalte befinden nach rechts schieben
Verwandte Funktionen
Beispiel
; ***************************************************************
; Beispiel 1 - Schreibt in einen Zellbereich unter Verwendung einer Schleife, fügt danach eine Spalte ein, dann wird gespeichert und die Datei geschlossen.
; *****************************************************************
#include <Excel.au3>
Local $oExcel = _ExcelBookNew() ; Erzeugt eine neue Mappe, macht sie sichtbar
For $i = 1 To 5 ; Schleife
_ExcelWriteCell($oExcel, $i, $i, 1) ; Schreibt in 5 Zellen (vertikale Richtung) die Werte 1 bis 5.
Next
ToolTip("Gleich gibts 'ne neue Spalte...")
Sleep(3500) ; Pause zum Beobachten
_ExcelColumnInsert($oExcel, 1, 1) ; Fügt eine Spalte vor Spalte 1 ein
MsgBox(0, "Beenden...", "Drücke OK, um die Datei zu speichern und Excel zu beenden.")
_ExcelBookSaveAs($oExcel, @TempDir & "\Temp.xls", "xls", 0, 1) ; Nun wird die Datei in das Temp-Verzeichnis gespeichert. Falls notwendig werden existierende Dateien überschrieben.
_ExcelBookClose($oExcel) ; Und zum Schluss schließen wir die Datei.
; ***************************************************************
; Beispiel 2 - Schreibt in einen Zellbereich unter Verwendung einer Schleife, fügt danach Spalten ein, dann wird gespeichert und die Datei geschlossen.
; *****************************************************************
#include <Excel.au3>
Local $oExcel = _ExcelBookNew() ; Erzeugt eine neue Mappe, macht sie sichtbar
; Man kann ein paar Zellen mit einer einfachen Schleife und Zufallszahlen ausfüllen.
For $i = 1 To 10
For $j = 1 To 10
_ExcelWriteCell($oExcel, Random(1, 100, 1), $i, $j) ; Integer-Zufallszahlen von 1 bis 99
Next
Next
ToolTip("Gleich gibts neue Spalten...")
Sleep(3500) ; Pause zum Beobachten
_ExcelColumnInsert($oExcel, 4, 3) ; Fügt 3 Spalten vor Spalte 4 ein
MsgBox(0, "Beenden...", "Drücke OK, um die Datei zu speichern und Excel zu beenden.")
_ExcelBookSaveAs($oExcel, @TempDir & "\Temp.xls", "xls", 0, 1) ; Nun wird die Datei in das Temp-Verzeichnis gespeichert. Falls notwendig werden existierende Dateien überschrieben.
_ExcelBookClose($oExcel) ; Und zum Schluss schließen wir die Datei.