Verschiebt das festgelegte Tabellenblatt vor ein anderes festgelegtes Tabellenblatt.
#Include <Excel.au3>
_ExcelSheetMove($oExcel, $vMoveSheet [, $vRelativeSheet = 1 [, $fBefore = True]])
Parameter
| $oExcel | Ein Excel Objekt welches durch einen vorherigen Aufruf von _ExcelBookOpen() oder _ExcelBookNew() geöffnet wurde |
| $vMoveSheet | Der Name oder die Zahl des zu verschiebenden Tabellenblattes (ein String oder Integer) |
| $vRelativeSheet | [optional] Das verschobene Tabellenblatt wird vor oder nach diesem Tabellenblatt platziert (ein String oder Integer, standardmäßig das erste Tabellenblatt) |
| $fBefore | [optional] True: das verschobene Tabellenblatt wird vor das relative Tabellenblatt platziert (Standard) False: das verschobene Tabellenblatt wird nach dem relativen Tabellenblatt platziert |
Rückgabewert
| Erfolg: | 1 |
| Fehler: | 0 und setzt @error |
| @error: | 0 - Kein Fehler |
| 1 - festgelegtes Objekt existiert nicht | |
| 2 - festgelegte zu verschiebende Tabellenblattzahl existiert nicht | |
| 3 - festgelegter zu verschiebender Tabellenblattname existiert nicht | |
| 4 - festgelegte relative Tabellenblattzahl existiert nicht | |
| 5 - festgelegter relativer Tabellenblattname existiert nicht |
Bemerkungen
Keine.
Verwandte Funktionen
Beispiel
; *****************************************************************
; Beispiel 1 - Nach dem Öffnen einer Arbeitsmappe und Rückgabe des Objekt-Handles: Verschiebt ein Arbeitsblatt und benutzt den Index-Wert des Arbeitsblatts
; *****************************************************************
#include <Excel.au3>
Local $oExcel = _ExcelBookNew() ; Erstellt eine neue Arbeitsmappe und zeigt sie an
_ExcelSheetMove($oExcel, 2) ; Verschiebt das zweite Blatt an die erste Position (String/Namen basierend)
MsgBox(0, "Verlassen", " Beachte: Blatt2 befindet sich jetzt an der ersten Position " & @CRLF & @CRLF & "Drücke OK um, die Datei zu Speichern und das Programm zu verlassen")
_ExcelBookSaveAs($oExcel, @TempDir & "\Temp.xls", "xls", 0, 1) ; Nun speichern wir die Datei, in eine temporäres Verzeichnis; existierende Dateien werden dabei überschrieben!
_ExcelBookClose($oExcel) ; Zum Abschluss verlassen wir das Programm
; *****************************************************************
; Beispiel 2 - Nach dem Öffnen einer Arbeitsmappe und Rückgabe des Objekt-Handles: Verschiebt ein Arbeitsblatt und benutzt den String-Namen des Arbeitsblatts
; *****************************************************************
#include <Excel.au3>
Local $oExcel = _ExcelBookNew() ; Erstellt eine neue Arbeitsmappe und zeigt sie an
_ExcelSheetMove($oExcel, "Blatt2") ; Verschiebt das zweite Blatt an die erste Position (String/Namen basierend)
MsgBox(0, "Verlassen", "Beachte: Blatt2 befindet sich jetzt an der ersten Position" & @CRLF & @CRLF & "Drücke nun OK um, die Datei zu Speichern und das Programm zu verlassen")
_ExcelBookSaveAs($oExcel, @TempDir & "\Temp.xls", "xls", 0, 1) ; Nun speichern wir die Datei, in eine temporäres Verzeichnis; existierende Dateien werden dabei überschrieben!
_ExcelBookClose($oExcel) ; Zum Abschluss verlassen wir das Programm
; ***************************************************************
; Beispiel 3 - Nach dem Öffnen einer Arbeitsmappe und Rückgabe des Objekt-Handles: Verschiebt ein Arbeitsblatt und benutzt dabei den Index Wert des Blatts
; *****************************************************************
#include <Excel.au3>
Local $oExcel = _ExcelBookNew() ; Erstellt eine neue Arbeitsmappe und zeigt sie an
; Hinzufügen eines weiteren Arbeitsblatts und ordne sie an
$sSheetName4 = "Blatt4"
$sSheetName5 = "Blatt5"
_ExcelSheetAddNew($oExcel, $sSheetName4) ; Hinzufügen eines weiteren Arbeitsblatts
_ExcelSheetMove($oExcel, $sSheetName4, 4, False) ; Verschiebt $sSheetName4 an die vierte Position (False, fügt das Blatt hinter dem relativen Blatt ein)
_ExcelSheetAddNew($oExcel, $sSheetName5) ; Hinzufügen eines weiteren Arbeitsblatts
_ExcelSheetMove($oExcel, $sSheetName5, 5, False) ; Verschiebt $sSheetName4 an die fünfte Position (False, fügt das Blatt hinter dem relativen Blatt ein)
MsgBox(0, "Anzeige", "Beachte die Reihenfolge der Arbeitsblätter" & @CRLF & @CRLF & "Drücke OK um fortzufahren")
_ExcelSheetMove($oExcel, $sSheetName5, "Blatt3", True) ; Verschiebt das fünfte Blatt zur relativen Position vor: 'Blatt3'
MsgBox(0, "Verlassen", "'" & $sSheetName5 & "'" & " wenn der $fBefore-Parameter True ist (Relative zu 'Blatt3')" & @CRLF & @CRLF & "Drücke OK um, die Datei zu Speichern und das Programm zu verlassen")
_ExcelSheetMove($oExcel, $sSheetName5, "Blatt3", False) ; Verschiebt das fünfte Blatt zur relativen Position vor: 'Blatt3'
MsgBox(0, "Verlassen", "'" & $sSheetName5 & "'" & " wenn der $fBefore-Parameter False ist (Relative zu 'Blatt3')" & @CRLF & @CRLF & "Drücke OK um, die Datei zu Speichern und das Programm zu verlassen")
_ExcelBookSaveAs($oExcel, @TempDir & "\Temp.xls", "xls", 0, 1) ; Nun speichern wir die Datei, in eine temporäres Verzeichnis; existierende Dateien werden dabei überschrieben!
_ExcelBookClose($oExcel) ; Zum Abschluss verlassen wir das Programm