Schreibt Informationen in eine Zelle der aktiven Excel-Datei des angegebenen Excel-Objekts.
#Include <Excel.au3>
_ExcelWriteCell($oExcel, $sValue, $sRangeOrRow [, $iColumn = 1])
Parameter
| $oExcel | Ein Excel-Objekt, welches durch einen vorherigen Aufruf von _ExcelBookOpen() oder _ExcelBookNew() geöffnet wurde |
| $sValue | zu schreibender Wert |
| $sRangeOrRow | Entweder ein A1-Bereich oder eine Integer-Zeilennummer, wenn die Bezugsart Z1S1 verwendet wird |
| $iColumn | [optional] Die Spalte, in die geschrieben werden soll, falls die Z1S1-Bezugsart verwendet wird (Standard = 1) |
Rückgabewert
| Erfolg: | 1 |
| Fehler: | 0 und setzt @error |
| @error: | 0 - Kein Fehler |
| 1 - angegebenes Objekt existiert nicht | |
| 2 - Parameter außerhalb des Bereichs | |
| @extended: | 0 - Zeile außerhalb des Bereichs |
| 1 - Spalte außerhalb des Bereichs |
Bemerkungen
Keine.
Verwandte Funktionen
Beispiel
; ***************************************************************
; Beispiel 1 - Schreibt in eine Zelle, nachdem eine neue Arbeitsmappe angelegt und deren Objekt-ID ermittelt wurde.
; Dann Speichern und Schließen der Datei.
; *****************************************************************
#include <Excel.au3>
Local $oExcel = _ExcelBookNew() ; Erzeugt eine neue Mappe, macht sie sichtbar
_ExcelWriteCell($oExcel, "Ich hab hier mal was rein geschrieben!", 3, 2) ; Schreibt in die Zelle [3,2]
MsgBox(0, "Beenden", "Drücke OK zum Speichern und Beenden.")
_ExcelBookSaveAs($oExcel, @TempDir & "\Temp.xls", "xls", 0, 1) ; Jetzt wird ins Temp-Verzeichnis gespeichert; wenn nötig, werden bestehende Dateien überschrieben
_ExcelBookClose($oExcel) ; Und schließlich machen wir die Mappe wieder zu.
; ***************************************************************
; Beispiel 2 - Schreibt mit Hilfe einer Schleife Daten in eine Zelle, nachdem eine neue Arbeitsmappe angelegt
; und deren Objekt-ID ermittelt wurde. Dann Speichern und Schließen der Datei.
; *****************************************************************
#include <Excel.au3>
Local $oExcel = _ExcelBookNew() ; Erzeugt eine neue Mappe, macht sie sichtbar
For $i = 1 To 20 ; Schleife
_ExcelWriteCell($oExcel, $i & ".: Ich schrieb in diese Zelle.", $i, 1) ; Schreibt in die Zelle [$i,1]
Next
MsgBox(0, "Beenden", "Drücke OK zum Speichern und Beenden.")
_ExcelBookSaveAs($oExcel, @TempDir & "\Temp.xls", "xls", 0, 1) ; Jetzt wird ins Temp-Verzeichnis gespeichert; wenn nötig, werden bestehende Dateien überschrieben
_ExcelBookClose($oExcel) ; Und schließlich machen wir die Mappe wieder zu.
; ***************************************************************
; Beispiel 3 - Schreibt mit Hilfe einer Schleife Daten in eine Zelle, nachdem eine neue Arbeitsmappe angelegt
; und deren Objekt-ID ermittelt wurde. Dann werden mit Formeln eingegeben und die Datei gespeichert und geschlossen.
; *****************************************************************
#include <Excel.au3>
Local $oExcel = _ExcelBookNew() ; Erzeugt eine neue Mappe, macht sie sichtbar
For $i = 1 To 20 ; Schleife
_ExcelWriteCell($oExcel, $i, $i, 1) ; Schreibt den Wert von $i in die Zelle [$i,1]
Next
_ExcelWriteCell($oExcel, "Schnitt:", 3, 3) ; Schreibt in die Zelle [3,3]
_ExcelWriteCell($oExcel, "Summe:", 5, 3) ; Schreibt in die Zelle [5,3]
_ExcelWriteCell($oExcel, "=Mittelwert(A:A)", 3, 4) ; Schreibt die Formel zur Berechnung des Mittelwerts der Daten in die Zelle [3,4] (benutzt die A1-Bezugsart, nicht Z1S1)
_ExcelWriteCell($oExcel, "=Summe(A1:A20)", 5, 4) ; Schreibt die Formel zur Berechnung der Summe der Daten in die Zelle [5,4] (benutzt eine weitere Variante der A1-Bezugsart, nicht Z1S1)
MsgBox(0, "Beenden", "Drücke OK zum Speichern und Beenden.")
_ExcelBookSaveAs($oExcel, @TempDir & "\Temp.xls", "xls", 0, 1) ; Jetzt wird ins Temp-Verzeichnis gespeichert; wenn nötig, werden bestehende Dateien überschrieben
_ExcelBookClose($oExcel) ; Und schließlich machen wir die Mappe wieder zu.