Erstellt einen einstellbaren Pfeil mit einer bestimmten Höhe und Breite
#Include <GDIPlus.au3>
_GDIPlus_ArrowCapCreate($fHeight, $fWidth[, $bFilled = True])
Parameter
| $fHeight | Bestimmt die Länge in Unites, wie weit die Pfeilspitze vom Startpunkt entfernt ist |
| $fWidth | Bestimmt die Distanz in Unites zwischen den beiden Enden der Pfeilspitze (Pfeilhöhe) |
| $bFilled | [optional] Füllflag: True - Pfeil wird gefüllt False - Pfeil wird nicht gefüllt |
Rückgabewert
| Erfolg: | Gibt ein Handle zu einem neuen Pfeil-Objekt zurück |
| Fehler: | 0 |
Bemerkungen
Nachdem die Funktion beendet wurde, sollte _GDIPlus_ArrowCapDispose aufgerufen werden, um das Objekt wieder aufzulösen
Verwandte Funktionen
_GDIPlus_ArrowCapDispose
Siehe auch
Suche in der MSDN Bibliothek nach GdipCreateAdjustableArrowCap
Beispiel
#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hGUI, $hGraphic, $hPen, $hEndCap
; Erstellt eine GUI
$hGUI = GUICreate("GDI+", 400, 300)
GUISetState()
; Erzeugt die Ressourcen
_GDIPlus_Startup()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
$hPen = _GDIPlus_PenCreate(0xFF000000, 2)
$hEndCap = _GDIPlus_ArrowCapCreate(3, 6)
_GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
; Ermittelt die benutzerdefinierte Endkappe des Zeichenstifts
MsgBox(4096, "Information", "Endkappe: 0x" & Hex(_GDIPlus_PenGetCustomEndCap($hPen)))
; Zeichnet Pfeile
_GDIPlus_GraphicsDrawLine($hGraphic, 10, 120, 390, 120, $hPen)
_GDIPlus_PenSetWidth($hPen, 4)
_GDIPlus_GraphicsDrawLine($hGraphic, 10, 150, 390, 150, $hPen)
_GDIPlus_PenSetWidth($hPen, 6)
_GDIPlus_GraphicsDrawLine($hGraphic, 10, 180, 390, 180, $hPen)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; Ressourcen freigeben
_GDIPlus_ArrowCapDispose($hEndCap)
_GDIPlus_PenDispose($hPen)
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_Shutdown()
EndFunc ;==>_Main