Ermittelt die Höhe der Pfeilspitze
#Include <GDIPlus.au3>
_GDIPlus_ArrowCapGetHeight($hArrowCap)
Parameter
| $hArrowCap | Handle zu dem Pfeil-Objekt |
Rückgabewert
| Erfolg: | Gibt die Höhe der Pfeilspitze zurück |
| Fehler: | 0 |
Bemerkungen
Die Höhe ist der Abstand von der Basis des Pfeils zu dessen Ecke
Verwandte Funktionen
_GDIPlus_ArrowCapSetHeight
Siehe auch
Suche in der MSDN Bibliothek nach GdipGetAdjustableArrowCapHeight
Beispiel
#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hGUI, $hGraphic, $hPen, $hEndCap
; Erstellt eine GUI
$hGUI = GUICreate("GDI+", 400, 300)
GUISetState()
; Erzeugt die Ressourcen
_GDIPlus_Startup()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
$hPen = _GDIPlus_PenCreate(0xFF000000, 4)
$hEndCap = _GDIPlus_ArrowCapCreate(3, 6)
_GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
; Zeichnet Pfeil 1
_GDIPlus_GraphicsDrawLine($hGraphic, 10, 120, 390, 120, $hPen)
; Zeichnet Pfeil 2
_GDIPlus_ArrowCapSetHeight($hEndCap, _GDIPlus_ArrowCapGetHeight($hEndCap) + 2)
_GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
_GDIPlus_GraphicsDrawLine($hGraphic, 10, 150, 390, 150, $hPen)
; Zeichnet Pfeil 3
_GDIPlus_ArrowCapSetHeight($hEndCap, _GDIPlus_ArrowCapGetHeight($hEndCap) + 2)
_GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
_GDIPlus_GraphicsDrawLine($hGraphic, 10, 180, 390, 180, $hPen)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; Ressourcen freigeben
_GDIPlus_ArrowCapDispose($hEndCap)
_GDIPlus_PenDispose($hPen)
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_Shutdown()
EndFunc ;==>_Main