Setzt die Farbe eines vollfarbigen Füllmuster-Objekts.
#Include <GDIPlus.au3>
_GDIPlus_BrushSetSolidColor($hBrush, [$iARGB = 0xFF000000])
Parameter
| $hBrush | Handle zu einem Füllmuster-Objekt |
| $iARGB | [optional] Alpha-, Rot-, Grün- und Blau-Komponenten eines Füllmusters |
Rückgabewert
| Erfolg: | True |
| Fehler: | False |
Bemerkungen
Keine.
Verwandte Funktionen
Siehe auch
Suche in der MSDN Bibliothek nach GdipSetSolidFillColor
Beispiel
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hGUI, $Label1, $label2, $hGraphic, $hBrush1, $iClr1, $iClr2
; Erstellt ein GUI
$hGUI = GUICreate("GDI+", 345, 150)
$Label1 = GUICtrlCreateLabel("", 2, 2, 150, 20)
$label2 = GUICtrlCreateLabel("", 202, 2, 150, 20)
GUISetState()
Sleep(100)
; Startet GDIPlus
_GDIPlus_Startup()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
; Erstellt ein einfarbiges Füllmuster
$hBrush1 = _GDIPlus_BrushCreateSolid()
; Originale Farbe des einfarbigen Füllmusters abfragen
$iClr1 = _GDIPlus_BrushGetSolidColor($hBrush1)
; Einige Grafiken mit der originalen Farbe des Füllmusters zeichnen
_GDIPlus_GraphicsFillEllipse($hGraphic, 25, 25, 100, 100, $hBrush1)
; Neue Füllmusterfarbe festlegen (0xFFFF0000 = Red)
_GDIPlus_BrushSetSolidColor($hBrush1, 0xFFFF0000)
; Neue Farbe des Füllmusters abfragen
$iClr2 = _GDIPlus_BrushGetSolidColor($hBrush1)
; Einige Grafiken mit der neuen Farbe des Füllmusters zeichnen
_GDIPlus_GraphicsFillRect($hGraphic, 220, 25, 100, 100, $hBrush1)
; Originale Füllmusterfarbe in Label1 schreiben
GUICtrlSetData($Label1, "Füllmuster orignale Farbe: " & Hex($iClr1))
; Neue Füllmusterfarbe in Label2 schreiben
GUICtrlSetData($label2, "Füllmuster neue Farbe: " & Hex($iClr2))
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion des GUI auslöst
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; Ressourcen freigeben
_GDIPlus_BrushDispose($hBrush1)
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_Shutdown()
EndFunc ;==>_Main