Funktionsreferenz

_GDIPlus_DrawImagePoints

Zeichnet ein Bild an einer festgelegten Stelle (Verzerrung möglich)

#Include <GDIPlus.au3>
_GDIPlus_DrawImagePoints($hGraphic, $hImage, $nULX, $nULY, $nURX, $nURY, $nLLX, $nLLY[, $count = 3])

 

Parameter

$hGraphic Handle zu einem Grafik-Objekt
$hImage Handle zu einem Bild-Objekt
$nULX Die X Koordinate der oberen linken Ecke des Quellbildes
$nULY Die Y Koordinate der oberen linken Ecke des Quellbildes
$nURX Die X Koordinate der oberen rechten Ecke des Quellbildes
$nURY Die Y Koordinate der oberen rechten Ecke des Quellbildes
$nLLX Die X Koordinate der unteren linken Ecke des Quellbildes
$nLLY Die Y Koordinate der unteren linken Ecke des Quellbildes
$count [optional] legt die Anzahl von Punkten (x,y) in der Struktur fest.

 

Rückgabewert

Erfolg: True
Fehler: False

 

Bemerkungen

Der Wert des count Parameters muss exakt 3 sein, um die Koordinaten der
oberen linken Ecke, der oberen rechten Ecke und der unteren linken Ecke des
Parallelogramms festzulegen. Die Koordinaten der unteren rechten Ecke, die Breite und die
Höhe des Bildes werden durch die drei gegebenen Koordinaten berechnet.
Das Bild wird skaliert, damit es in das Parallelogramm passt.

 

Verwandte Funktionen

 

Siehe auch

Suche in der MSDN Bibliothek nach GdipDrawImagePoints

 

Beispiel


#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GDIPlus.au3>
#include <ScreenCapture.au3>

Opt('MustDeclareVars', 1)

_Main()

Func _Main()
    Local $hBitmap1, $hBitmap2, $hImage1, $hImage2, $hGraphic

    ; Initialisiert (startet) Microsoft Windows GDI+
    _GDIPlus_Startup()

    ; Erstellt vom kompletten Bildschirm einen Screenshot
    $hBitmap1 = _ScreenCapture_Capture("")
    $hImage1 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap1)

    ; Erstellt von einem Bereich einen Screenshot
    $hBitmap2 = _ScreenCapture_Capture("", 0, 0, 400, 300)
    $hImage2 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap2)

    ; Zeichnet ein Bild in ein anderes
    $hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage1)

    _GDIPlus_DrawImagePoints($hGraphic, $hImage2, 100, 100, 600, 170, 130, 570)

    ; Zeichnet einen Rahmen um das eingefügte Bild
    _GDIPlus_GraphicsDrawRect($hGraphic, 100, 100, 400, 300)

    ; Speichert das neue Bild
    _GDIPlus_ImageSaveToFile($hImage1, @MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Ressourcen freigeben
    _GDIPlus_ImageDispose($hImage1)
    _GDIPlus_ImageDispose($hImage2)
    _WinAPI_DeleteObject($hBitmap1)
    _WinAPI_DeleteObject($hBitmap2)

    ; Gibt die durch Microsoft Windows GDI+ verwendeten Ressourcen wieder frei
    _GDIPlus_Shutdown()

EndFunc   ;==>_Main