Funktionsreferenz

_GDIPlus_FontFamilyCreate

Erstellt ein Schriftenfamilien-Objekt

#include <GDIPlus.au3>
_GDIPlus_FontFamilyCreate($sFamily)

Parameter

$sFamily

Name der Schriftfamilie

Rückgabewert

Erfolg:	Handle zu einem Schriftenfamilien-Objekt
Fehler:	0

Bemerkungen

Wenn man mit dem Schriftenfamilien-Objekt fertig ist, ist _GDIPlus_FontFamilyDispose aufzurufen, um die Ressourcen wieder freizugeben

Siehe auch

Suche in der MSDN Bibliothek nach GdipCreateFontFamilyFromName

Beispiel

#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>

_Main()

Func _Main()
Local $hGUI, $hGraphic, $hBrush, $hFormat, $hFamily, $hFont, $tLayout

; Erstellt eine GUI
$hGUI = GUICreate("GDI+", 400, 300)
GUISetState()

; Zeichnet einen String
_GDIPlus_Startup()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
$hBrush = _GDIPlus_BrushCreateSolid(0x7F00007F)
$hFormat = _GDIPlus_StringFormatCreate()
$hFamily = _GDIPlus_FontFamilyCreate("Arial")
$hFont = _GDIPlus_FontCreate($hFamily, 12, 2)
$tLayout = _GDIPlus_RectFCreate(140, 110, 100, 20)
_GDIPlus_GraphicsDrawStringEx($hGraphic, "Hallo Welt", $hFont, $tLayout, $hFormat, $hBrush)

; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

; Ressourcen freigeben
_GDIPlus_FontDispose($hFont)
_GDIPlus_FontFamilyDispose($hFamily)
_GDIPlus_StringFormatDispose($hFormat)
_GDIPlus_BrushDispose($hBrush)
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_Shutdown()

EndFunc ;==>_Main