Erstellt ein Grafik-Objekt aus einem Gerätekontext
#Include <GDIPlus.au3>
_GDIPlus_GraphicsCreateFromHDC($hDC)
Parameter
| $hDC | Handle zu einem Gerätekontext |
Rückgabewert
| Erfolg: | Handle zu einem Grafik-Objekt |
| Fehler: | 0 |
Bemerkungen
Wenn man mit dem Grafik-Objekt fertig ist, ist _GDIPlus_GraphicsDispose aufzurufen um die Ressourcen wieder freizugeben
Verwandte Funktionen
_GDIPlus_GraphicsDispose
Siehe auch
Suche in der MSDN Bibliothek nach GdipCreateFromHDC
Beispiel
#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
#include <WinAPI.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hGUI, $hGraphic, $hBrush, $hFormat, $hFamily, $hFont, $tLayout, $hDC
; Erstellt eine GUI
$hGUI = GUICreate("GDI+", 400, 300)
$hDC = _WinAPI_GetWindowDC($hGUI)
GUISetState()
; Zeichnet einen String
_GDIPlus_Startup()
$hGraphic = _GDIPlus_GraphicsCreateFromHDC($hDC)
$hBrush = _GDIPlus_BrushCreateSolid(0x7F00007F)
$hFormat = _GDIPlus_StringFormatCreate()
$hFamily = _GDIPlus_FontFamilyCreate("Arial")
$hFont = _GDIPlus_FontCreate($hFamily, 12, 2)
$tLayout = _GDIPlus_RectFCreate(140, 110, 100, 20)
_GDIPlus_GraphicsDrawStringEx($hGraphic, "Hallo Welt", $hFont, $tLayout, $hFormat, $hBrush)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; Ressourcen freigeben
_GDIPlus_FontDispose($hFont)
_GDIPlus_FontFamilyDispose($hFamily)
_GDIPlus_StringFormatDispose($hFormat)
_GDIPlus_BrushDispose($hBrush)
_GDIPlus_GraphicsDispose($hGraphic)
_WinAPI_ReleaseDC($hGUI, $hDC)
_GDIPlus_Shutdown()
EndFunc ;==>_Main