Zeichnet ein Bild an einer festgelegten Stelle
#Include <GDIPlus.au3>
_GDIPlus_GraphicsDrawImageRect($hGraphics, $hImage, $iX, $iY, $iW, $iH )
Parameter
| $hGraphics | Handle zu einem Grafik-Objekt |
| $hImage | Handle zu einem Bild-Objekt |
| $iX | Die X Koordinate der oberen linken Ecke des gerenderten Bildes |
| $iY | Die Y Koordinate der oberen linken Ecke des gerenderten Bildes |
| $iW | legt die Breite des Zielrechtecks fest, an dem das Bild gezeichnet werden soll |
| $iH | legt die Höhe des Zielrechtecks fest, an dem das Bild gezeichnet werden soll |
Rückgabewert
| Erfolg: | True |
| Fehler: | False |
Bemerkungen
Keine.
Verwandte Funktionen
Siehe auch
Suche in der MSDN Bibliothek nach GdipDrawImageRectI
Beispiel
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hBitmap1, $hBitmap2, $hImage1, $hImage2, $hGraphic
; Initialisiert (startet) Microsoft Windows GDI+
_GDIPlus_Startup()
; Erstellt vom kompletten Bildschirm einen Screenshot
$hBitmap1 = _ScreenCapture_Capture("")
$hImage1 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap1)
; Erstellt von einem Bereich einen Screenshot
$hBitmap2 = _ScreenCapture_Capture("", 0, 0, 400, 300)
$hImage2 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap2)
; Zeichnet ein Bild in ein anderes
$hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage1)
_GDIPlus_GraphicsDrawImageRect($hGraphic, $hImage2, 100, 100, 400, 300)
; Zeichnet einen Rahmen um das eingefügte Bild
_GDIPlus_GraphicsDrawRect($hGraphic, 100, 100, 400, 300)
; Speichert das neue Bild
_GDIPlus_ImageSaveToFile($hImage1, @MyDocumentsDir & "\GDIPlus_Image.jpg")
; Ressourcen freigeben
_GDIPlus_ImageDispose($hImage1)
_GDIPlus_ImageDispose($hImage2)
_WinAPI_DeleteObject($hBitmap1)
_WinAPI_DeleteObject($hBitmap2)
; Gibt die durch Microsoft Windows GDI+ verwendeten Ressourcen wieder frei
_GDIPlus_Shutdown()
EndFunc ;==>_Main