Gibt eine Aufzählung von Pixeldatenattributen zurück, die in einem Bild enthalten sind
#Include <GDIPlus.au3>
_GDIPlus_ImageGetFlags($hImage)
Parameter
| $hImage | Handle zu einem Bild-Objekt |
Rückgabewert
| Erfolg: | Array mit dem folgenden Format |
| [0] - Integer-Flagsatz mit Pixeldatenattributen | |
| [1] - String von Pixeldatenattributen, Trennung mit "|" | |
| Fehler: | Gibt ein leeres Array zurück und setzt @error. @extended wird auf den Fehlerbereich gesetzt |
| @error: | 0 - kein Fehler |
| 10 - ungültiges Bildhandle |
Bemerkungen
@error 4 basiert auf der GDIPlus-UDF, welche im Fehlerfall -1 oder 0 anstelle eines Bildhandles zurückgibt.
Verwandte Funktionen
_GDIPlus_ImageGetPixelFormat
Siehe auch
Suche in der MSDN Bibliothek nach GdipGetImageFlags
Beispiel
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>
Opt('MustDeclareVars', 1)
Global $iMemo
_Main()
Func _Main()
Local $hBitmap, $hImage, $aRet
; Erstellt das GUI
GUICreate("GDI+", 600, 400)
$iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; Initialisiert (startet) Microsoft Windows GDI+
_GDIPlus_Startup()
; Erstellt vom kompletten Bildschirm einen Screenshot und erzeugt daraus eine 32-bit Bitmap
$hBitmap = _ScreenCapture_Capture("")
$hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)
; Zeigt die Pixeldaten-Eigenschaften des Screenshots
$aRet = _GDIPlus_ImageGetFlags($hImage)
$aRet[1] = @CRLF & StringReplace($aRet[1], "|", @CRLF)
MemoWrite("Pixeldaten-Eigenschaften des Screenshots: " & $aRet[1]);
MemoWrite();
MemoWrite("Integer-Flag-Satz mit Pixeldaten-Attributen: " & $aRet[0]);
MemoWrite();
; Speichert den Screenshot (Bitmap) in einer Datei
_GDIPlus_ImageSaveToFile($hImage, @MyDocumentsDir & "\GDIPlus_Image.jpg")
; Ressourcen freigeben
_GDIPlus_ImageDispose($hImage)
_WinAPI_DeleteObject($hBitmap)
; Lädt den Screenshot (Bitmap) aus einer Datei
$hImage = _GDIPlus_ImageLoadFromFile(@MyDocumentsDir & "\GDIPlus_Image.jpg")
; Zeigt die Pixeldaten-Eigenschaften des abgespeicherten Screenshots (Bitmap)
$aRet = _GDIPlus_ImageGetFlags($hImage)
$aRet[1] = @CRLF & StringReplace($aRet[1], "|", @CRLF)
MemoWrite("Pixeldaten-Eigenschaften der gespeicherten Datei: " & $aRet[1]);
MemoWrite();
MemoWrite("Integer-Flag-Satz mit Pixeldaten-Attributen: " & $aRet[0]);
; Ressourcen freigeben
_GDIPlus_ImageDispose($hImage)
; Gibt die durch Microsoft Windows GDI+ verwendeten Ressourcen wieder frei
_GDIPlus_Shutdown()
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; Gibt eine Zeile im Memo Fenster aus
Func MemoWrite($sMessage = '')
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite