Gibt zu einem Bild die GUID des Dateiformats und den Namen des Imageformats zurück.
#Include <GDIPlus.au3>
_GDIPlus_ImageGetRawFormat($hImage)
Parameter
| $hImage | Handle auf ein Bild-Objekt |
Rückgabewert
| Erfolg: | Array mit dem folgenden Format |
| [0] - - String mit GUID des Dateiformats | |
| [1] - - String mit dem Namen des Imageformats | |
| Fehler: | Gibt ein leeres Array zurück und Makro @error ist gesetzt. Makro @extended wird auf die Fehlerposition gesetzt. |
| @error: | 0 - Kein Fehler. |
| 10 - Ungültiges Handle des Bild-Objekts |
Bemerkungen
Der Rückgabewert 4 des Makros @error beruht darauf, dass die GDI+ UDF im Fehlerfall -1 oder 0 anstelle des Bild-Handles zurückgibt.
Verwandte Funktionen
_GDIPlus_ImageGetType
Siehe auch
Suche in der MSDN Bibliothek nach GdipGetImageRawFormat
Beispiel
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>
Opt('MustDeclareVars', 1)
Global $iMemo
_Main()
Func _Main()
Local $hBitmap, $hImage, $aRet
; Erstellt eine GUI
GUICreate("GDI+", 600, 400)
$iMemo = GUICtrlCreateEdit("", 2, 2, 606, 196, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; Initialisiert (startet) Microsoft Windows GDI+
_GDIPlus_Startup()
; Erstellt vom kompletten Bildschirm einen Screenshot und erzeugt daraus eine 32 bit Bitmap
$hBitmap = _ScreenCapture_Capture("")
$hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)
; Gibt das Bildformat des Screenshots zurück
$aRet = _GDIPlus_ImageGetRawFormat($hImage)
MemoWrite("String mit dem Namen des Bildformats: " & $aRet[1]);
MemoWrite("String mit der GUID des Dateiformats: " & $aRet[0]);
MemoWrite();
; Speichert die Screenshot-Bitmap in eine Datei
_GDIPlus_ImageSaveToFile($hImage, @MyDocumentsDir & "\GDIPlus_Image.jpg")
; Ressourcen freigeben
_GDIPlus_ImageDispose($hImage)
_WinAPI_DeleteObject($hBitmap)
; Lädt die Screenshot-Bitmap aus einer Datei
$hImage = _GDIPlus_ImageLoadFromFile(@MyDocumentsDir & "\GDIPlus_Image.jpg")
; Gibt das Bildformat der gespeicherten Datei zurück
$aRet = _GDIPlus_ImageGetRawFormat($hImage)
MemoWrite("String mit dem Namen des Bildformats: " & $aRet[1]);
MemoWrite("String mit der GUID des Dateiformats: " & $aRet[0]);
; Ressourcen freigeben
_GDIPlus_ImageDispose($hImage)
; Gibt die durch Microsoft Windows GDI+ verwendeten Ressourcen wieder frei
_GDIPlus_Shutdown()
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; Gibt eine Zeile im Memo-Fenster aus
Func MemoWrite($sMessage = '')
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite