Gibt die vertikale Auflösung in DPI (Punkte pro Zoll) eines Bildes zurück
#Include <GDIPlus.au3>
_GDIPlus_ImageGetVerticalResolution($hImage)
Parameter
| $hImage | Handle zu einem Bild-Objekt |
Rückgabewert
| Erfolg: | Integer mit DPI (Punkte pro Zoll) |
| Fehler: | gibt 0 zurück und setzt @error |
| @error: | 0 - kein Fehler. |
| 10 - ungültiges Bild Handle |
Bemerkungen
@error 4 basiert auf einem Rückgabewert von -1 oder 0 durch die GDIPlus-UDF anstelle des Bild-Handles im Fehlerfall
Verwandte Funktionen
_GDIPlus_ImageGetHorizontalResolution
Siehe auch
Suche in der MSDN Bibliothek nach GdipGetImageVerticalResolution
Beispiel
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>
Opt('MustDeclareVars', 1)
Global $iMemo
_Main()
Func _Main()
Local $hBitmap, $hImage
; Erstellt eine GUI
GUICreate("GDI+", 600, 400)
$iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; Initialisiert (startet) Microsoft Windows GDI+
_GDIPlus_Startup()
; Erstellt vom kompletten Bildschirm einen Screenshot und erzeugt daraus eine 32 bit Bitmap
$hBitmap = _ScreenCapture_Capture("")
$hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)
; Zeigt die vertikale Auslösung des Bildes in DPI (dots per inch)
MemoWrite("VerticalResolution DPI : " & _GDIPlus_ImageGetVerticalResolution($hImage));
; Ressourcen freigeben
_GDIPlus_ImageDispose($hImage)
_WinAPI_DeleteObject($hBitmap)
; Gibt die durch Microsoft Windows GDI+ verwendeten Ressourcen wieder frei
_GDIPlus_Shutdown()
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; Gibt eine Zeile im Memo-Fenster aus
Func MemoWrite($sMessage = '')
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite