Fügt einen Wert zu einer Encoder-Parameter-Liste hinzu.
#Include <GDIPlus.au3>
_GDIPlus_ParamAdd(ByRef $tParams, $sGUID, $iCount, $iType, $pValues)
Parameter
| $tParams | $tagGDIPPENCODERPARAMS Struktur zurückgegeben aus _GDIPlus_ParamInit |
| $sGUID | Encoder Parameter GUID. Kann einer der folgenden Optionen sein: $GDIP_EPGCHROMINANCETABLE - Einstellungen der Farbwert-Tabelle $GDIP_EPGCOLORDEPTH - Einstellungen der Farbtiefe $GDIP_EPGCOMPRESSION - Einstellungen der Komprimierung $GDIP_EPGLUMINANCETABLE - Einstellungen der Leuchtdichte-Tabelle $GDIP_EPGQUALITY - Qualitätseinstellungen $GDIP_EPGRENDERMETHOD - Einstellungen der Render-Methode $GDIP_EPGSAVEFLAG - Einstellungen der Speichern-Flag $GDIP_EPGSCANMETHOD - Einstellungen des Scan-Modus $GDIP_EPGTRANSFORMATION - Transformationseinstellungen $GDIP_EPGVERSION - Einstellungen der Software-Version |
| $iCount | Anzahl der Elemente im Array $pValues |
| $iType | Encoder Typ des Parameter Wertes. Kann einer der folgenden Optionen sein: $GDIP_EPTBYTE - 8 Bit vorzeichenloser Integer (unsigned integer) $GDIP_EPTASCII - Null-terminierter String $GDIP_EPTSHORT - 16 Bit vorzeichenloser Integer (unsigned integer) $GDIP_EPTLONG - 32 Bit vorzeichenloser Integer (unsigned integer) $GDIP_EPTRATIONAL - Zwei longs (Zähler, Nenner) $GDIP_EPTLONGRANGE - Zwei longs (low, high) $GDIP_EPTUNDEFINED - Array von Bytes (jedes Typs) $GDIP_EPTRATIONALRANGE - Zwei abwechselnde (low, high) |
| $pValues | Zeiger auf ein Array von Werten. Jeder Wert hat den Typ, der von dem Datenelement $iType festgelegt wurde. |
Rückgabewert
Keine.
Bemerkungen
Keine.
Verwandte Funktionen
_GDIPlus_ParamInit, $tagGDIPPENCODERPARAMS
Beispiel
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hBitmap, $hImage, $sCLSID, $tData, $tParams
; Erstellt vom kompletten Bildschirm einen Screenshot
_ScreenCapture_Capture(@MyDocumentsDir & "\GDIPlus_Image.jpg")
; Initialisiert (startet) Microsoft Windows GDI+
_GDIPlus_Startup()
; Lädt ein Bild
$hImage = _GDIPlus_ImageLoadFromFile(@MyDocumentsDir & "\GDIPlus_Image.jpg")
; Gibt die Encoder CLSID für einen festgelegten Bild-Dateityp zurück
$sCLSID = _GDIPlus_EncodersGetCLSID("JPG")
; Setzt die Parameter für eine 90 Grad Rotation
$tData = DllStructCreate("int Data")
DllStructSetData($tData, "Data", $GDIP_EVTTRANSFORMROTATE90)
$tParams = _GDIPlus_ParamInit(1)
_GDIPlus_ParamAdd($tParams, $GDIP_EPGTRANSFORMATION, 1, $GDIP_EPTLONG, DllStructGetPtr($tData, "Data"))
; Speichert das gedrehte Bild
_GDIPlus_ImageSaveToFileEx($hImage, @MyDocumentsDir & "\GDIPlus_Image2.jpg", $sCLSID, DllStructGetPtr($tParams))
; Gibt die durch Microsoft Windows GDI+ verwendeten Ressourcen wieder frei
_GDIPlus_Shutdown()
EndFunc ;==>_Main