Ermittelt den Stil der Strich-Endkappe des Zeichenstiftes
#Include <GDIPlus.au3>
_GDIPlus_PenGetDashCap($hPen)
Parameter
| $hPen | Handle zu einem Zeichenstift-Objekt |
Rückgabewert
| Erfolg: | Stil der einzelnen Striche: |
| $GDIP_DASHCAPFLAT - Eine quadratische Endkappe, die beide Enden jeder Linie abflacht | |
| $GDIP_DASHCAPROUND - Eine kreisförmige Endkappe, die beide Enden jeder Linie abrundet | |
| $GDIP_DASHCAPTRIANGLE - Eine dreieckige Endkappe, die beide Enden jeder Linie anspitzt | |
| Fehler: | -1 und @error wird gesetzt |
Bemerkungen
Keine.
Verwandte Funktionen
_GDIPlus_PenSetDashCap
Siehe auch
Suche in der MSDN Bibliothek nach GdipGetPenDashCap197819
Beispiel
#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hGUI, $hGraphic, $hPen
; Erstellt eine GUI
$hGUI = GUICreate("GDI+", 400, 300)
GUISetState()
; Erzeugt die Ressourcen
_GDIPlus_Startup()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
$hPen = _GDIPlus_PenCreate(0xFF000000, 8)
_GDIPlus_PenSetDashStyle($hPen, $GDIP_DASHSTYLEDASHDOT)
_GDIPlus_PenSetDashCap($hPen, $GDIP_DASHCAPTRIANGLE)
; Den Stil der Strich-Endkappe des Zeichenstiftes anzeigen
MsgBox(4096, "Information", "Strich-Endkappe des Zeichenstiftes: " & _GDIPlus_PenGetDashCap($hPen))
; Zeichnet eine Linie
_GDIPlus_GraphicsDrawLine($hGraphic, 10, 150, 390, 150, $hPen)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; Ressourcen freigeben
_GDIPlus_PenDispose($hPen)
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_Shutdown()
EndFunc ;==>_Main