Simuliert einen Klick auf einen Button
#Include <GuiButton.au3>
_GUICtrlButton_Click($hWnd)
Parameter
| $hWnd | Handle zu dem Control |
Rückgabewert
Keine.
Bemerkungen
Falls der Button sich in einem Diagogfenster befindet und dieses nicht aktiv ist, könnte _GUICtrlButton_Click fehlschlagen.
Verwandte Funktionen
Siehe auch
Suche in der MSDN Bibliothek nach BM_CLICK
Beispiel
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIConstantsEx.au3>
#include <GuiButton.au3>
Opt("MustDeclareVars", 1)
Global $btn[6], $iMemo, $iRand
HotKeySet("!b", "Clickit")
_Main()
Func _Main()
Local $y = 70
GUICreate("Buttons", 610, 400)
$iMemo = GUICtrlCreateEdit("", 119, 10, 476, 374, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
MemoWrite("Drücke Alt+b, um einen zufällig ausgewählten Button zu drücken.")
$btn[0] = GUICtrlCreateButton("Button1", 10, 10, 100, 50)
For $x = 1 To 5
$btn[$x] = GUICtrlCreateButton("Button" & $x + 1, 10, $y, 100, 50)
$y += 60
Next
$iRand = Random(0, 5, 1)
_GUICtrlButton_SetText($btn[$iRand], "Neuer Text " & $iRand + 1)
GUISetState()
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop
Case $btn[$iRand]
MemoWrite(_GUICtrlButton_GetText($btn[$iRand]) & " angeklickt")
EndSwitch
WEnd
Exit
EndFunc ;==>_Main
Func Clickit()
$iRand = Random(0, 5, 1)
_GUICtrlButton_Click($btn[$iRand])
EndFunc ;==>Clickit
; Gibt eine Zeile im Memo-Fenster aus
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite