Ermittelt die Breite der aufgeklappten ListBox einer ComboBox.
#Include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetDroppedWidth($hWnd)
Parameter
| $hWnd | Handle des Controls |
Rückgabewert
Erfolg: Die Breite in Pixel
Bemerkungen
Die ComboBox muss den Stil $CBS_DROPDOWN oder $CBS_DROPDOWNLIST aufweisen.
Verwandte Funktionen
_GUICtrlComboBox_GetDroppedState, _GUICtrlComboBoxEx_SetDroppedWidth
Beispiel
#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GuiConstantsEx.au3>
Opt('MustDeclareVars', 1)
$Debug_CB = False ; Prüft den Klassennamen (ClassName), der an die ComboBox/ComboBoxEx-Funktion übergeben wird. Setze dies versuchsweise auf True und verwende dann ein Handle zu einem anderen Control, um die Funktionsweise zu verstehen.
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $hImage, $hCombo
; Erstellt eine GUI
$hGUI = GUICreate("ComboBoxEx: Ermittelt die minimal erlaubte Breite der ListBox", 400, 300)
$hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
$iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
$hImage = _GUIImageList_Create(16, 16, 5, 3)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
_GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
_GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)
For $x = 0 To 8
_GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Zufallstring", Random(1, 100, 1)), $x, $x)
Next
; Ermittelt die minimal erlaubte Breite der ListBox
MemoWrite("minimal erlaubte Breite......: " & _GUICtrlComboBoxEx_GetDroppedWidth($hCombo))
Sleep(500)
; Zeigt das Dropdown
_GUICtrlComboBoxEx_ShowDropDown($hCombo, True)
Sleep(500)
; Versteckt das Dropdown
_GUICtrlComboBoxEx_ShowDropDown($hCombo)
; Setzt die minimal erlaubte Breite der ListBox
_GUICtrlComboBoxEx_SetDroppedWidth($hCombo, 500)
Sleep(500)
; Ermittelt die minimal erlaubte Breite der ListBox
MemoWrite("minimal erlaubte Breite......: " & _GUICtrlComboBoxEx_GetDroppedWidth($hCombo))
Sleep(500)
; Zeigt das Dropdown
_GUICtrlComboBoxEx_ShowDropDown($hCombo, True)
Sleep(500)
; Versteckt das Dropdown
_GUICtrlComboBoxEx_ShowDropDown($hCombo)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
; Gibt eine Zeile im Memo-Fenster aus
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite