Funktionsreferenz

_GUICtrlComboBoxEx_GetItem

Ermittelt Attribute eines Items

#Include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetItem($hWnd, $iIndex)

 

Parameter

$hWnd Handle des Controls
$iIndex 0-basierender Itemindex

 

Rückgabewert

Erfolg: Array mit dem folgenden Format:
    [0] - Itemtext
    [1] - Länge des Itemtextes
    [2] - Anzahl von Bilderbreiten um das Bild einzurücken
    [3] - 0-basierender Itembilderindex
    [4] - 0-basierender Itemstatusbilderindex
    [5] - 0-basierender Item Bilder Overlay Index
    [6] - anwendungsspezifischer Wert

 

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

 

Verwandte Funktionen

_GUICtrlComboBoxEx_SetItem, _GUICtrlComboBoxEx_GetItemEx

 

Beispiel


#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GuiConstantsEx.au3>

Opt('MustDeclareVars', 1)

$Debug_CB = False ; Prüft den Klassennamen (ClassName), der an die ComboBox/ComboBoxEx-Funktion übergeben wird. Setze dies versuchsweise auf True und verwende dann ein Handle zu einem anderen Control, um die Funktionsweise zu verstehen.

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hImage, $aItem, $hCombo
   
    ; Erstellt eine GUI
    $hGUI = GUICreate("ComboBoxEx: Ermittelt Attribute eines Items", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 100)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    $hImage = _GUIImageList_Create (16, 16, 5, 3)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList ($hCombo, $hImage)

    For $x = 0 To 8
        _GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Zufallstring", Random(1, 100, 1)), $x, $x)
    Next

    ; Setzt den Einrückwert der Items 1 und 3
    _GUICtrlComboBoxEx_SetItemIndent ($hCombo, 1, 1)
    _GUICtrlComboBoxEx_SetItemIndent ($hCombo, 3, 1)

    $aItem = _GUICtrlComboBoxEx_GetItem ($hCombo, 3)
    MemoWrite("Item Text: " & $aItem[0])
    MemoWrite("Länge des Item-Textes ......................: " & $aItem[1])
    MemoWrite("Anzahl der Bilderbreiten bis zur Einrückung : " & $aItem[2])
    MemoWrite("0-basierender Itembilderindex ..............: " & $aItem[3])
    MemoWrite("0-basierender Itemstatusbilderindex ........: " & $aItem[4])
    MemoWrite("0-basierender Itembilder-Overlay-Index: ....: " & $aItem[5])
    MemoWrite("Anwendungsspezifischer Wert ................: " & $aItem[6])
   
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; Gibt eine Zeile im Memo-Fenster aus
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite