Setzt einige oder alle Attribute eines Items.
#Include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetItem($hWnd, $sText[, $iIndex = 0[, $iImage = -1[, $iSelectedImage = -1[, $iOverlayImage = -1[, $iIndent = -1[, $iParam = -1]]]]]])
Parameter
| $hWnd | Handle des Controls |
| $sText | Itemtext |
| $iIndex | [optional] Der 0-basierende Index des Items |
| $iImage | [optional] 0-basierender Index des Item Icons in der Imagelist des Controls |
| $iSelectedImage | [optional] 0-basierender Index des Item Icons in der Imagelist des Controls |
| $iOverlayImage | [optional] 0-basierender Index des Item Icons in der Imagelist des Controls |
| $iIndent | [optional] Anzahl von Bilderbreiten um das Item einzurücken. Eine einfache Einrückung entspricht der Breite eines Bildes. |
| $iParam | [optional] Wert der das Item spezifiziert |
Rückgabewert
| Erfolg: | True |
| Fehler: | False |
Bemerkungen
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
_GUICtrlComboBoxEx_GetItem, _GUICtrlComboBoxEx_SetItemEx
Beispiel
#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GuiConstantsEx.au3>
Opt('MustDeclareVars', 1)
$Debug_CB = False ; Prüft den Klassennamen (ClassName), der an die ComboBox/ComboBoxEx-Funktion übergeben wird. Setze dies versuchsweise auf True und verwende dann ein Handle zu einem anderen Control, um die Funktionsweise zu verstehen.
_Main()
Func _Main()
Local $hGUI, $hImage, $iImage, $hCombo
; Erstellt eine GUI
$hGUI = GUICreate("ComboBoxEx: Item setzen", 400, 300)
$hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
GUISetState()
$hImage = _GUIImageList_Create(16, 16, 5, 3)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
_GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
_GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)
_GUICtrlComboBoxEx_InitStorage($hCombo, 150, 300)
_GUICtrlComboBoxEx_BeginUpdate($hCombo)
For $x = 0 To 149
$iImage = Random(0, 8, 1)
_GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Zufallstring", Random(1, 100, 1)), $iImage, $iImage)
Next
_GUICtrlComboBoxEx_EndUpdate($hCombo)
; Ändert Item 2
MsgBox(4160, "Information", "Ändert Item 2")
_GUICtrlComboBoxEx_SetItem($hCombo, "Neues Item 2", 1)
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main