Ermittelt Informationen über die festgelegte ComboBox
#Include <GuiComboBox.au3>
_GUICtrlComboBox_GetComboBoxInfo($hWnd, ByRef $tInfo)
Parameter
| $hWnd | Handle des Controls |
| $tInfo | Infos die durch $COMBOBOXINFO definiert sind. |
Rückgabewert
| Erfolg: | True |
| Fehler: | False |
Bemerkungen
Mindestvoraussetzung Betriebssystem: Windows XP
Verwandte Funktionen
Beispiel
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIComboBox.au3>
#include <GuiConstantsEx.au3>
#include <Constants.au3>
Opt('MustDeclareVars', 1)
$Debug_CB = False ; Prüft den Klassennamen (ClassName), der an die ComboBox/ComboBoxEx-Funktion übergeben wird. Setze dies versuchsweise auf True und verwende dann ein Handle zu einem anderen Control, um die Funktionsweise zu verstehen.
Global $iMemo
_Main()
Func _Main()
Local $tInfo, $hCombo
; Erstellt eine GUI
GUICreate("ComboBox: Informationen ermitteln", 400, 296)
$hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
$iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; Fügt Dateien hinzu
_GUICtrlComboBox_BeginUpdate($hCombo)
_GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
_GUICtrlComboBox_EndUpdate($hCombo)
If _GUICtrlComboBox_GetComboBoxInfo($hCombo, $tInfo) Then
MemoWrite("Handle der ComboBox ........: " & DllStructGetData($tInfo, "hCombo"))
MemoWrite("Handle der EditBox .........: " & DllStructGetData($tInfo, "hEdit"))
MemoWrite('Handle der "Drop-down"-Liste: ' & DllStructGetData($tInfo, "hList"))
EndIf
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
; Gibt eine Zeile im Memo-Fenster aus
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite