Ermittelt den "cue banner" Text, welcher in einem Edit-Control einer Combobox angezeigt wird
#Include <GuiComboBox.au3>
_GUICtrlComboBox_GetCueBanner($hWnd)
Parameter
| $hWnd | Handle des Controls |
Rückgabewert
Erfolg: Der "cue banner" Text
Bemerkungen
Der "cue banner" ist Text, welcher in dem Edit-Control einer ComboBox dargestellt wird, wenn kein Item markiert ist
Verwandte Funktionen
_GUICtrlComboBox_SetCueBanner
Beispiel
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIComboBox.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
$Debug_CB = False ; Prüft den Klassennamen (ClassName), der an die ComboBox/ComboBoxEx-Funktion übergeben wird. Setze dies versuchsweise auf True und verwende dann ein Handle zu einem anderen Control, um die Funktionsweise zu verstehen.
; Benötigt mindestens Windows Vista!
Global $iMemo
_Main()
Func _Main()
Local $hCombo
; Erstellt eine GUI
GUICreate("ComboBox: Hinweistext setzen und auslesen", 400, 296)
$iMemo = GUICtrlCreateEdit("", 10, 50, 376, 234, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
$hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
; Setzt den "cue banner"-Hinweistext der Combobox
_GUICtrlComboBox_SetCueBanner($hCombo, "Wähle ein Item aus")
GUISetState()
; Fügt Dateien hinzu
_GUICtrlComboBox_BeginUpdate($hCombo)
_GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
_GUICtrlComboBox_EndUpdate($hCombo)
; Liest den Hinweistext aus und schreibt ihn ins Memo
MemoWrite("Combobox-Hinweis: " & _GUICtrlComboBox_GetCueBanner($hCombo))
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
; Schreibt eine Zeile in das Memo Control
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite