Funktionsreferenz

_GUICtrlComboBox_InsertString

Fügt einen String ein

#include <GuiComboBox.au3>
_GUICtrlComboBox_InsertString($hWnd, $sText [, $iIndex = -1])

Parameter

$hWnd Control-ID / Handle des Controls
$sText einzufügender String
$iIndex [optional] legt den 0-basierenden Index fest, vor welchen der String eingefügt werden soll.

Rückgabewert

Erfolg: 0-basierender Index, vor welchen der String eingefügt werden soll.
Fehler: -1

Bemerkungen

Falls der $iIndex Parameter –1 ist, wird der String an das Ende der Liste eingefügt.

Falls die ComboBox den Stil $WS_HSCROLL aufweist und ein String eingefügt wird der größer ist als die ComboBox, so sollte _GUICtrlComboBox_SetHorizontalExtent verwendet werden um sicherzustellen, dass die horizontale Scrollbar erscheint.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlComboBox_AddString, _GUICtrlComboBox_InitStorage

Beispiel


#include <GUIComboBox.au3>
#include <GuiConstantsEx.au3>

$Debug_CB = False ; Prüft den Klassennamen (ClassName), der an die ComboBox/ComboBoxEx-Funktion übergeben wird. Setze dies versuchsweise auf True und verwende dann ein Handle zu einem anderen Control, um die Funktionsweise zu verstehen.

_Main()

Func _Main()
    Local $hCombo

    ; Erstellt eine GUI
    GUICreate("ComboBox: String einfügen", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    GUISetState()

    ; Fügt Dateien hinzu
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; String einfügen
    _GUICtrlComboBox_InsertString($hCombo, "Ein eingefügter String", 0)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main