Funktionsreferenz

_GUICtrlTreeView_AddChild

Fügt ein neues Child-Item Am Ende hinzu

#include <GuiTreeView.au3>
_GUICtrlTreeView_AddChild($hWnd, $hParent, $sText [, $iImage = -1 [, $iSelImage = -1]])

Parameter

$hWnd Control-ID / Handle des Controls
$hParent Parent-Item
$sText Text des Items
$iImage [optional] 0-basierender Index des Itemicons in der Imagelist des Controls
$iSelImage [optional] 0-basierender Index des Itemicons in der Imagelist des Controls

Rückgabewert

Erfolg: Das Handle zu dem neuen Item
Fehler: 0

Bemerkungen

Das Item wird als Child-Item von $hParent hinzugefügt. Es wird an das Ende von $hParent hinzugefügt. Falls das Control sortiert wird, wird das Item an die korrekte sortierte Position gesetzt, anstatt als letztes Child-Item von $hParent.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlTreeView_AddChildFirst

Beispiel


#include <GuiConstantsEx.au3>
#include <GuiTreeView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; Prüft den Klassennamen (ClassName), der an die TreeView-Funktion übergeben wird. Setze dies versuchsweise auf True und verwende dann ein Handle zu einem anderen Control, um die Funktionsweise zu verstehen.

_Main()

Func _Main()

    Local $hItem, $hImage, $iImage, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView: Child hinzufügen", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
    _GUICtrlTreeView_SetNormalImageList($hTreeView, $hImage)

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 1 To Random(2, 10, 1)
        $iImage = Random(0, 5, 1)
        $hItem = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] Neues Item", $x), $iImage, $iImage)
        For $y = 1 To Random(2, 10, 1)
            $iImage = Random(0, 5, 1)
            _GUICtrlTreeView_AddChild($hTreeView, $hItem, StringFormat("[%02d] Neues Child", $y), $iImage, $iImage)
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main